Конкурс BASIC 10 Liner Contest

[Nick]

NewLogo_edited.png

Щорічний конкурс 10-рядкових програм на BASIC розпочав у 2011 Гуннар Канольд, ентузіаст ретрокомп'ютингу, який викладає STEM-предмети у середній школі Фрідріхштадту в Німеччині. Метою конкурсу є написання найбільш вражаючої гри в усього 10 рядках на BASIC, без підпрограм у машинних кодах. Є три категорії, що обмежують максимальну дозволену довжину рядка: PUR-80, PUR-120 і PUR-256. Існує також категорія SCHAU-256 для неігрового програмного забезпечення, та WILD для робіт, які не вписуються у жодну іншу категорію. Програма має працювати на 8-розрядному комп'ютері — наприклад, Atari, для якого існує емулятор.

[Nick]

Конкурс є міжнародним, але протягом 2019-2023 років я був єдиним учасником з України, зайнявши 1-ше (SCHAU-256) та 3-тє (PUR-120) місця у 2021-му, та 2-ге місце (PUR-256) у 2022-му. Запрошую всіх українських фанатів ретрокомп'ютингу до участі!

[Nick]

Перший раз я прийняв участь у конкурсі в 2019 році. Одразу поставив собі амбітну мету — реалізувати гру Color Lines для ZX Spectrum.
Теоретично мені це вдалося (категорія EXTREME-256):

ColorLines.png

Проте практично грати неможливо — обрахунок шляху кульки з точки A у точку B здійснюється занадто повільно. Повноцінно грати можна хіба що в емуляторі, вибравши максимальну швидкість.
Код гри:

► Показати

Код: Виділити все

0 PAPER 7:INK 7:CLS:DIM g(6):DIM h(6):FOR i=0 TO 39:READ b:POKE USR ("A")+i,b:NEXT i:FOR i=7 TO 23 STEP 2:FOR j=3 TO 19 STEP 2:PRINT AT j,i;"\a\b";AT j+1,i;"\c\d";:NEXT j:NEXT i:FOR i=1 TO 6:READ g(i),h(i):NEXT i:READ b$,c$:LET z=0:REM ZX Spectrum Basic
1 DIM f(25,25):DIM t(25,25):LET n=81:LET s=0:LET u=13:LET v=13:LET c=0:LET d=0:PAPER 7:FOR i=1 TO 12:PRINT INK INT((i+1)/2);AT 21,9+i;c$(i);:NEXT i:LET a$="HI SCORE "+STR$ z:PRINT INK 0;AT 2,25-LEN a$;a$;:FOR m=1 TO 5:GOSUB 7:NEXT m:PAPER 0:REM Tenliner
2 PRINT FLASH 0;BRIGHT 1;INK 7;AT 2*v-14,2*u-10;"\e";:LET a$=INKEY$:FOR i=1 TO 4:IF a$=b$(i) AND u+g(i)>=9 AND u+g(i)<18 AND v+h(i)>=9 AND v+h(i)<18 THEN PRINT FLASH u=c AND v=d;BRIGHT 0;INK f(u,v);AT 2*v-14,2*u-10;"\d";:LET u=u+g(i):LET v=v+h(i):GOTO 2
3 NEXT i:IF a$<>" " OR c=0 AND f(u,v)=0 THEN PRINT PAPER 7;INK 0;AT 2,7;s;"   ":GOTO 2:DATA 0,3,15,25,55,47,111,127,0,192,240,232,244,250,244,250,127,127,63,63,31,15,3,0,244,250,244,252,232,240,192,0,255,254,252,254,255,254,220,136,-1,0,0,-1,1,0,0:REM 
4 DIM t(25,25):IF f(u,v) THEN LET c=c+u*NOT c:LET d=d+v*NOT d:LET a=22037+64*d+2*c:LET b=f(c,d):POKE a,b:POKE a+1,b:POKE a+32,b:POKE a+33,b:LET c=u:LET d=v:LET a=22037+64*d+2*c:LET b=128+f(c,d):POKE a,b:POKE a+1,b:POKE a+32,b:POKE a+33,b:GOTO 2:REM 2019
5 LET t(c,d)=1:LET m=0:FOR i=9 TO 17:FOR j=9 TO 17:FOR k=1 TO 4:LET p=i+g(k):LET q=j+h(k):LET r=t(p,q):LET t(p,q)=r OR t(i,j) AND NOT f(p,q):LET m=m OR t(p,q)<>r:NEXT k:NEXT j:NEXT i:GOTO 4*t(u,v)+3*(m AND NOT t(u,v))+2:DATA 1,1,1,1,-1:REM "EXTREME-256"
6 DIM t(25,25):LET f(u,v)=f(c,d):LET f(c,d)=0:LET c=0:LET d=0:LET x=u:LET y=v:LET m=n:GOSUB 8:BEEP m<>n,7:FOR m=1 to 3*(m=n):GOSUB 7:NEXT m:GOTO 2:DATA "oqpa","COLOR  LINES":REM Written by Nick Shcherbyna, Lviv, Ukraine <computer.history.lviv@gmail.com>
7 LET p=0:LET q=INT(n*RND)+1:LET x=0:LET y=0:FOR i=9 TO 17:FOR j=9 TO 17:LET p=p+NOT f(i,j):LET x=x+(p=q)*i:LET y=y+(p=q)*j:LET q=q AND NOT x:NEXT j:NEXT i:LET f(x+NOT p,y+NOT p)=INT(7*RND)+1:LET n=n-1:IF p=0 THEN LET z=(s>z)*s+(s<=z)*z:BEEP 1,13:GOTO 1
8 FOR i=3 TO 6:LET l=0:LET p=1:LET r=0:LET q=1:FOR j=1 TO 8:LET p=p AND f(x,y)=f(x-j*g(i),y-j*h(i)):LET l=l-p:LET q=q AND f(x,y)=f(x+j*g(i),y+j*h(i)):LET r=r+q:NEXT j:FOR j=l TO r:LET p=x+j*g(i):LET q=y+j*h(i):LET t(p,q)=t(p,q) OR r+1-l>=5:NEXT j:NEXT i
9 FOR i=9 TO 17:FOR j=9 TO 17:LET f(i,j)=f(i,j) AND NOT t(i,j):LET n=n+t(i,j):LET s=s+t(i,j):LET t(i,j)=0:NEXT j:NEXT i:FOR i=9 TO 17:FOR j=9 TO 17:LET a=22037+64*j+2*i:LET b=f(i,j):POKE a,b:POKE a+1,b:POKE a+32,b:POKE a+33,b:NEXT j:NEXT i:RETURN:REM ;)

Супровідний лист (англ.):

► Показати

The Color Lines is an interesting puzzle for implementation. There are two important algorithms: 1) once new ball is moved by player or placed by computer, find all horizontal, vertical, and diagonal lines of 5 (or more) balls and eliminate them; 2) check whether moving is possible (i.e., the ball can reach the destination without crossing other balls).
My version presents rather nice graphics (to be honest, color balls came from Exolon), and mostly resembles the original. I don't show three colors that will appear, and don't animate the ball step-by-step. However, all game rules are correctly implemented in my tenliner.
Now bad news. The game works painfully slow. To play in BasinC (my development environment) I turn on acceleration by pressing [F1] (turning off only for moving the ball). Otherwise it takes minutes before the next move.
Personally for me, the challenge was to implement core algorithms in 3 lines of ZX BASIC, and I did it. But the game is almost unplayable on a real Speccy :-(

Опис гри (англ.):

► Показати

Color Lines is a turn-based board game. Each turn, three randomly colored balls fall on random grids of a 9x9 squares board. Your mission is to re-locate the balls (by moving one of them per turn) to form lines consisting of five or more balls of the same color. The lines can be arranged vertically, horizontally, or diagonally. Each line you build immediately disappears, giving you points. There is basically no end to the game. You lose when the entire board is filled with balls.

Controls: [Q], [A], [O], [P], [SPACE].

Let me explain the code.
Line 0: arrays g and h represent horizontal and vertical directions, respectively. Directions are left, up, right, down, right-down, right-up. Elements 1-4 are used to move the ball by keyboard, elements 3-6 are used to detect lines. Then ball (16x16) and arrow (8x8) sprites are loaded as UDG characters. Playfield (9x9) is populated by invisible ball sprites, we'll change screen attributes to make color balls. Variable z is high score.
Line 1: initializing playfield f(25,25) and temporary t(25,25). Note that we really use 9x9 playfield (indices 9 to 17), other elements are needed for simplification of algorithms. Variable n is a counter of free cells, s is score, u and v are arrow coordinates, c and d are selected ball coordinates. Then I write the game title and high score. Finally, 5 initial balls are born: subroutine 7 creates one.
Line 2: drawing the arrow, asking for keypress, if it is up (Q), down (A), left (O), or right (P) - erasing the previous arrow and updating coordinates, then doing 2 again.
Line 3: if the key pressed is not SPACE or the current cell is empty and no ball has been selected, then write the current score (not the place to do so) and loop to 2.
Line 4: Clean the temporary matrix. If there is a ball in the current cell, unmark the previous ball (remove FLASH attribute) and mark the new one (set FLASH attribute). If no ball was selected I unmark the current one before marking it (avoiding IF statement). Loop to 2.
Line 5: So it is a new destination. Recursive filling of temporary matrix to reach the starting point. If no places were discovered on the current step (variable m), loop to 2. If can be reached, go to 6. Otherwise one more step, loop to 5.
Line 6: Clean the temporary matrix. Move the ball to new destination, reset mark. Subroutine 8 checks whether any line of >=5 balls appeared and removes them. Beep if so, born 3 balls otherwise. Loop to 2.
Line 7: Subroutine, born a new ball. We always know the number of free cells (n), so pick the random cell from that category. If impossible, update high score, beep, and restart the game from line 1.
Line 8: Subroutine, checking whether any line of >=5 balls appear. There are 4 directions (indices 3 to 6): horizontal, vertical, and two diagonals. Counting backward and forward (here extra zeroed elements are acessed), if sum >=5 then mark in the temporary matrix.
Line 9: Subroutine, redraw the playfield (by updating screen attributes). Before that we remove balls marked in temporary matrix (continuing line 8). For other contexts it is harmless (but time wasting). Return from any of subroutines (entry points are 7, 8, and 9).

Як то кажуть, "перший млинець нанівець" — гра зайняла передостаннє місце у категорії:

► Показати

results.png

[Nick]

Після явної невдачі з Color Lines, вирішив спробувати себе у "найменшій" категорії PUR-80. У грі Pixels Attack зверху падають великі квадратні пікселі різних кольорів, які треба ловити білим квадратиком. Все максимально просто і тупо:

PixelsAttack.png

Код гри:

► Показати

Код: Виділити все

0 BRIGHT 1:READ x,y,a$,b$,s:BORDER 0:PAPER 0:CLS:DIM c(32):DIM p(32):DATA 15, 11
1 RESTORE:FLASH 1:INK 7:PRINT AT 11,13;b$;AT 12,13;"ATTACK":BEEP 2,0:FLASH 0:CLS
2 FOR i=1 TO 32:LET z=22528+32*y+x:LET c(i)=c(i) AND p(i)<>z:POKE z, 255:LET r=0
3 IF p(i)=0 AND RND<.05 THEN LET c(i)=8*(INT(6*RND)+1):LET p(i)=22528+i:REM Nick
4 IF p(i)>22592 AND p(i)<23360 THEN POKE p(i)-64,7: DATA "GAME OVER!","PIXELS",0
5 IF p(i)>22560 AND p(i)<23328 THEN POKE p(i)-32,c(i)+7:LET r=NOT c(i):LET s=s+r
6 IF p(i) AND p(i)<23296 THEN POKE p(i),c(i)+71:LET p(i)=p(i)+32 AND c(i):REM ;)
7 LET k$=INKEY$: IF p(i)>=23296 THEN BORDER 2:PRINT AT 11,11;a$;:GO TO 7*(k$="")
8 LET x=x-(k$="o" AND x>0): LET x=x+(k$="p" AND x<31): IF r THEN PRINT AT 0,0;s;
9 LET y=y-(k$="q" AND y>1): LET y=y+(k$="a" AND y<22): POKE z,7: NEXT i: GO TO 2

Опис гри (англ.):

► Показати

       PIXELS ATTACK for Sinclair ZX Spectrum, category "PUR-80"
 ---------------------------------------------------------------------
  "Some alien life force has sent real-life video games to attack us"

Large deadly color pixels are descenting. To stop them, player controls
the white pixel trap by [Q]/[A]/[O]/[P] keys. The trap should be placed
exactly below the falling pixel. Game is lost if any pixel achieves the
bottom. Each catched pixel increases the score. If trap crosses a pixel
on its way, enemy disappears for a short time, but then appears again.

The code is simple enough. Pixel addresses (in screen attributes VRAM)
are stored in p(32), the corresponding colors - in c(32). Pixel is not
active if p(i)=0. Trap coordinates are x and y, z is the corresponding
attribute address.
This game works well in BasinC IDE, various emulators, and on the real
Speccy.

Звісно, така примітивна гра зайняла лише 25-те місце, що втім зовсім непогано:

► Показати

results.png

[Nick]

Якщо помітили, у результатах на 18-й позиції фігурує ще одна гра Pixels Attack. Я портував попередню гру на маловідому в нас платформу Mattel Aquarius.
Код гри:

► Показати

Код: Виділити все

0 ?CHR$(11);"PIXELS ATTACK ";: DIMp(40): DIMc(40): READu,x,y: SOUND(y,u)
1 FORa=13312TO14311:POKEa-1024,32:POKEa,112:NEXT: f$=CHR$(7):v=u+1:w=v+1
2 FORi=1TO40: z=13352+40*y+x:d=PEEK(z):POKEz,7: POKEw,48:POKEv,1:POKEu,0
3 t=p(i)=z: IFp(i)=0ANDRND(1)<0.04THENc(i)=INT(6*RND(1))+1: p(i)=13351+i
4 n=NOTt:s=s-t:c(i)=nANDc(i): IFp(i)>13431ANDp(i)<14392THENPOKEp(i)-80,0
5 IFp(i)>13391ANDp(i)<14352THENPOKEp(i)-40,c(i)>0AND15-c(i): IFtTHEN?f$;
6 IFp(i)ANDp(i)<14312THENPOKEp(i),c(i):p(i)=c(i)>0ANDp(i)+40: IFtTHEN?s;
7 k$=INKEY$:POKE14351,0:IFp(i)>14311THEN?"GAME OVER!!!";:SOUND(u,13):RUN
8 x=x+(k$="o"ANDx>0):x=x-(k$="p"ANDx<39):IFPEEK(z)=7THENPOKEz,d:REM Nick
9 y=y+(k$="q"ANDy>1):y=y-(k$="a"ANDy<23):NEXT:GOTO2:DATA14336,19,12,2019

[Nick]

Хоча мій дебют у 2019-му видався не дуже вдалим, а 2020-й довелося пропустити через проблеми зі здоров'ям, 2021-й став роком триумфу. Почав я з гри Volleyring (Sonic vs Shadow), де двоє їжаків з всесвіту SEGA грають у схожу на волейбол гру з кільцем замість м'яча (категорія EXTREME-256, платформа MSX):

SCRSHOT1.PNG

SCRSHOT2.PNG

Син намалював cover art:

Cover.png

Можете пограти прямо зараз.
Код гри:

► Показати

Код: Виділити все

0COLOR11,7,1:SCREEN2,2,0:OPEN"GRP:"AS#1:DEFSTRA-G:DEFINTH-Z:DEFFNR(V,S,M)=V/SANDMOR(VANDM)*S:DIMM(2),K(2),A(6):K(1)=2:K(2)=1:DEFFNK(J)=STICK(K(J)):READE,A(1):A(2)=E+"1":A(3)=E+"2":LINE(0,160)-(255,183),2,BF:READE,F,A(4),A(5),J,G:CIRCLE(9,9),33:PAINT(9,9)
1DEFFNM(V)=FNR(FNR(FNR(V,2,85),4,51),16,15):FORI=0TO7:READL:A=CHR$(L)+A+CHR$(L):R=FNM(L):B=CHR$(R)+B+CHR$(R):NEXT:SPRITE$(4)=A+B:A="":B="":FORI=0TO21:READL,R:A=A+CHR$(L):B=B+CHR$(R):C=C+CHR$(FNM(R)):D=D+CHR$(FNM(L)):NEXT:DEFFNJ(J)=(J=0AND(T=1ORT=2ORT=8))
2SPRITE$(0)=LEFT$(A,16)+LEFT$(B,16):SPRITE$(1)=LEFT$(A,10)+RIGHT$(A,6)+LEFT$(B,10)+RIGHT$(B,6):SPRITE$(2)=LEFT$(C,16)+LEFT$(D,16):SPRITE$(3)=LEFT$(C,10)+RIGHT$(C,6)+LEFT$(D,10)+RIGHT$(D,6):SPRITE$(5)=STRING$(16,3)+STRING$(16,192):PUTSPRITE5,(120,144),&HE
3M(1)=0:M(2)=0:H=11:FORX=0TO252STEP4:LINE(X,158)-(X,165),12:LINE(X+2,159)-(X+2,166),12:FORY=168TO180STEP4:LINE(X,Y)-(X+3,Y+3),H,BF:H=17-H:NEXT:H=17-H:NEXT:U=40:X=200:Y=144:W=0:Z=0:V=0:N=0:P=U+160*INT(2*RND(-TIME)):Q=120:R=0:S=0:RESTORE8:READA,B,C,D:PLAYE
4GOSUB9:PSET(88,U),0:PRINT#1,A;SPC(112);B;A(4);A(K(1)+1):PRINT#1,SPC(5);C;A(5);A(K(2)+1):PRINT#1,SPC(5);F;SPC(48);D:T=ASC(INKEY$+"0")AND15:IFT=0ORT>4THEN4ELSELINE(32,U)-(223,Q),7,BF:IFT<3THENK(T)=(K(T)+1)MOD3:GOTO4ELSEIFT=4THENSWAPA(5),G:J=10-J:GOTO4';-)
5T=FNK(1):W=8*FNJ(W):PUTSPRITE0,(U,Y+W),4,((W/4ORU)AND-4*(T>0))/4:U=U+4*(U>0ANDT>5)-4*(U<108ANDT>1ANDT<5):T=FNK(2):Z=8*FNJ(Z):PUTSPRITE2,(X,Y+Z),J,2+((Z/4ORX)AND-4*(T>0))/4:X=X+4*(X>132ANDT>5)-4*(X<240ANDT>1ANDT<5):T=P:P=P+R:Q=Q+S:PUTSPRITE4,(P,Q),10'MSX
6N=N*-((P<128)=(T<128)):IFW<0ANDABS(P-U)<16ANDQ>119ANDQ<133THENBEEP:R=(P-U+2)/3:S=-SQR(25-R*R):V=0:N=N+1:GOTO7::DATA":Joystick #",":Cursor Keys","L8O5EC#C#DO4B4O5C#EC#C#DO4B4O5C#C#C#O4AGBAO5EAER64G#A","[S] START GAME!","SONIC","SHADOW",1,"AMY R.",112,112
7IFZ<0ANDABS(P-X)<16ANDQ>119ANDQ<133THENBEEP:R=(P-X-2)/3:S=-SQR(25-R*R):V=0:N=N+1:GOTO8::DATA56,60,31,15,3,0,7,196,30,252,62,124,15,254,30,118,60,34,124,138,252,138,31,244,14,14,25,54,61,252,3,96,3,224,7,240,7,248,31,54,127,253,147,98,110,182,12,28,24,24
8V=(V+1)AND127:S=S-((VAND7)=0):R=R+SGN(R)*(V=0):IFN>3ORQ>143ORQ>132ANDABS(P-120)<8THENPLAY"L64O6BAGA":T=P<128:P=-X*T-U*NOTT:T=T+2:M(T)=M(T)+1:GOSUB9:Q=120:R=0:S=0:V=0:N=0:GOTO5ELSER=R*SGN(1+2*(P<1ORP>239)):S=S*SGN(1+2*(Q<1ORQ>143)):GOTO5:DATA"VOLLEYRING"
9T=15:LINE(0,184)-(255,191),4,BF:COLORT:PSET(24,184),0:PRINT#1,USING"[##] & vs. & [##]";M(2);A(4);A(5);M(1);:IFT=M(1)ORT=M(2)THENCOLOR8:PSET(72,56),0:PRINT#1,A(5+(M(2)=T));" winner!";:RETURN3ELSECOLOR1:RETURN:DATA"[1]  ","[2] ","(c) 2021 Nick Shcherbyna"

Опис гри (англ.):

► Показати

+------------------------------------------------------------------------------+
|   __      ______  _      _      ________     _______  _____ _   _  _____     |
|   \ \    / / __ \| |    | |    |  ____\ \   / /  __ \|_   _| \ | |/ ____|    |
|    \ \  / / |  | | |    | |    | |__   \ \_/ /| |__) | | | |  \| | |  __     |
|     \ \/ /| |  | | |    | |    |  __|   \   / |  _  /  | | | . ` | | |_ |    |
|      \  / | |__| | |____| |____| |____   | |  | | \ \ _| |_| |\  | |__| |    |
|       \/   \____/|______|______|______|  |_|  |_|  \_\_____|_| \_|\_____|    |
|      _____             _            _____ _               _                  |
|     / ____|           (_)          / ____| |             | |                 |
|    | (___   ___  _ __  _  ___     | (___ | |__   __ _  __| | _____      __   |
|     \___ \ / _ \| '_ \| |/ __|     \___ \| '_ \ / _` |/ _` |/ _ \ \ /\ / /   |
|     ____) | (_) | | | | | (__  VS  ____) | | | | (_| | (_| | (_) \ V  V /    |
|    |_____/ \___/|_| |_|_|\___|    |_____/|_| |_|\__,_|\__,_|\___/ \_/\_/     |
|                                                                              |
|                        EXTREME-256 BASIC game for MSX                        |
|                                                                              |
| (c) 2021 Nick Shcherbyna (Lviv, Ukraine)     computer.history.lviv@gmail.com |
+------------------------------------------------------------------------------+
| Instructions /                                                               |
|--------------                                                                |
|                                                                              |
| Hedgehogs cannot play volleyball because their spines might pierce the ball. |
| Instead they choose volleyring - essentially the same game, but using a ring |
| from Sonic's universe. The rules are simple: send a ring to opponent's side, |
| don't touch the net or ground. Hedgehog have to jump to strike the ring, but |
| three consecutive contacts with it is a fault. Match is played to 15 points. |
|                                                                              |
| Left player is Sonic the Hedgehog, right player is Shadow the Hedgehog. Both |
| are controlled by players using joysticks or cursor keys. Press [ 1 ] in the |
| main menu to choose Sonic's controls, press [ 2 ] to pick Shadow's controls. |
| Press [ S ] to start match. Note that there is an easter egg in the game!    |
|                                                                              |
| The game is written in MSX BASIC, and can run even on MSX1. For crazy action |
| pick MSX Turbo R. If you do not have real hardware, use emulator like WebMSX |
| (https://webmsx.org/).
|                                                                              |
| General tips:                                                                |
| For single-player action choose the same controls for Sonic and Shadow. Then |
| you will control both hedgehogs simultaneously. Playing with someone else is |
| likely more enjoyable, but this mode is good for practice.                   |
|                                                                              |
| WebMSX tips:                                                                 |
| Copy BASIC source to clipboard, then press [ Alt ]-[ V ] and [ Ctrl ]-[ V ], |
| after that press [ F5 ] to run the game.                                     |
| Press [ Alt ]-[ T ] to change the CPU frequency (and game speed).            |
| Press [ Alt ]-[ K ] several times to activate double joysticks emulation via |
| keyboard. Note that the first joystick is mapped to cursor keys, and the 2nd |
| one is mapped to [ F ] (left), [ T ] (jump), and [ H ] (right).              |
|                                                                              |
| Alternatively, one can run game from disk, either automatically or manually: |
| LOAD "VOLLEY10.BAS",R                                                        |
|                                                                              |
+------------------------------------------------------------------------------+
| Disk Contents /                                                              |
|---------------                                                               |
|                                                                              |
| AUTOEXEC.BAS - Autoloader                                                    |
| VOLLEY10.SC2 - Splash screen                                                 |
| README.TXT   - This document                                                 |
| VOLLEY10.BAS - 10-Liner game                                                 |
|                                                                              |
+------------------------------------------------------------------------------+
| Source Code Explained /                                                      |
|-----------------------                                                       |
|                                                                              |
| Variables:                                                                   |
| (U, Y + W) - Sonic's coordinates. Y is constant, W becomes negative on jump, |
|              otherwise 0.                                                    |
| (X, Y + Z) - Shadow's coordinates, like above.                               |
| (P, Q) - Ring coordinates.                                                   |
| (R, S) - Ring speed vector. Mirrored on screen bounds, updated when hedgehog |
|          strikes the ring in jump. V is used to simulate physics - every 128 |
|          steps |R| is decreasing, and every 8 steps S is increasing.         |
| N - Number of consecutive contacts. Reset to 0 when the ring passes the net. |
| T - Temporary variable, mostly used for joystick and keyboard readings.      |
| M(2) - Array of scores per player.                                           |
| K(2) - Array of controls per player (i.e., STICK() arguments).               |
| A(3) - Array of control names (cursor keys, joystick 1/2).                   |
|                                                                              |
| Functions:                                                                   |
| FNM(V)     - Mirroring bits in byte V. Used to generate Shadow's sprite from |
|              Sonic in three steps (C code):                                  |
|              V = ((V >> 1) & 0x55) | ((V & 0x55) << 1); // 1) Swap bits      |
|              V = ((V >> 2) & 0x33) | ((V & 0x33) << 2); // 2) Swap pairs     |
|              V = ((V >> 4) & 0x0F) | ((V & 0x0F) << 4); // 3) Swap nibbles   |
| FNR(V,S,M) - Helper function for FNM(V), performs single step from above.    |
| FNK(J) - Wrapper for STICK() for player J.                                   |
| FNJ(J) - Helper for jumps. Assumes T is STICK() reading. Argument is W or Z, |
|          for Sonic or Shadow. Returns -1 if stick is up and jump is allowed, |
|          0 otherwise.                                                        |
|                                                                              |
| Tricks:                                                                      |
| As already stated above, Shadow's sprite is mirrored from Sonic. Also, first |
| ten scanlines of two Sonic's sprites are similar, so there is no 2nd copy.   |
| Ring is generated from its quarter by mirroring horizontally and vertically. |
| Net is created using STRING$(), as the same pattern for all scanlines.       |
| Many IF statements are replaced by math, since MSX BASIC represents FALSE as |
| 0, and TRUE as -1. An example of this technique is changing ring vector when |
| it touches screen bounds: R=R*SGN(1+2*(P<1ORP>239)). The result of SGN is -1 |
| for bounds, 1 otherwise.                                                     |
|                                                                              |
| Lines:                                                                       |
| 0 Initialize graphics screen, define integer and string variable prefixes to |
|   save on % and $, prepare control names, draw grass and sun.                |
| 1 Define helper functions, define the ring sprite, prepare hedgehog sprites. |
| 2 Define hedgehog sprites, define and draw the net.                          |
| 3 Initialize core variables, draw checkered ground, finish grass, play intro |
|   music.                                                                     |
| 4 Display game title, copyright, and main menu. Keyboard handling for menu.  |
| 5 Control handling and sprite moving for Sonic, then do the same for Shadow. |
|   Move the ring by the current speed vector.                                 |
| 6 Reset the consecutive contacts counter if needed. Handle Sonic's strike.   |
| 7 Handle Shadow's strike.                                                    |
| 8 Simulate ring physics. Check for all faults, update score and variables if |
|   needed. Otherwise flip the speed vector, if the ring hits screen bounds.   |
| 9 Subroutine that shows score and checks for victory. If so, puts the winner |
|   name and restarts the game.                                                |
|                                                                              |
+------------------------------------------------------------------------------+
| Acknowledgements /                                                           |
|------------------                                                            |
|                                                                              |
| Thanks to my son Dan for the game idea, ad picture and sprites.              |
| Thanks to SEGA for Sonic and Shadow hedgehog characters.                     |
| Thanks to Microsoft and ASCII Corp. for MSX BASIC and machines.              |
| Thanks to Arcade Voleyball authors for some inspiration.                     |
|                                                                              |
+------------------------------------------------------------------------------+

Думаю, гра заслуговувала більш ніж на 12-те місце:

► Показати

results.png

[monoxrom]

А у таких малих іграх, наприклад у останній, сам персонаж "сонік" це як він намальований? просто якийсь двохвимірний масив пікселів?

[Nick]

Далі спробував себе у категорії PUR-80 для екзотичного Mattel Aquarius. Такий собі спрощений Lode Runner під назвою Escape, де іншопланетянин тікає з сумнозвісного Ангару 18, а робот-охоронець намагається його затримати:

SCRSHOT1.PNG

SCRSHOT2.PNG

Намалював cover art:

Cover.png

Код гри використовував процедурну генерацію рівнів:

► Показати

Код: Виділити все

0A=13248:FORY=0TO24:FORX=1TO38:Z=YAND3:R=RND(2*(S=0)+X+Y):L=PEEK(A+X+40)
1H=172:M=134:L=Z=1ANDL=MANDC<>HANDR<.2ORZ<>1ANDL=H:F=Z=LAND(C=32ORR<.98)
2C=32-102*(Y=0ORF)-140*L:POKEA+X,C:NEXTX:A=A-40:NEXTY:U=38:V=4:X=1:Y=6*V
3W=A+40*V+U:A$=CHR$(7):IFX=UANDY=VTHENPOKEW,209:?A$;A$;A$;CHR$(11);:RUN!
4Z=A+40*Y+X:B=PEEK(Z):C=PEEK(Z+40):POKEZ,146+(X+YAND1):K=PEEK(14346)-111
5X=X+(X>1ANDK=0ANDC>32)-(X<38ANDK=1ANDC>32):Y=Y+(B=HANDK=-14):IFY=0THEN9
6Y=Y-(C=32ORC=HANDK=11)::D=PEEK(W)::E=PEEK(W+40)::F=14+5*(U+VAND-(E>32))
7POKEW,F-11*(E=32):L=(V<YANDE<>MORE=32)-(V>YANDD=H):REM(c)NickShcherbyna
8U=U+(L=0)*SGN(U-X):V=V-L:FORI=5*STO50:NEXT:POKEZ,B:POKEW,D:GOTO3ESCAPE!
9S=S+1:?CHR$(11);"CONGRATS! Level";S;"/5 completed!";A$;A$;A$:IFS<5THEN0

Опис гри (англ.):

► Показати

          ___  ______  _____  _____          _____  ______ _  ___
        _/__/ |  ____|/ ____|/ ____|   /\   |  __ \|  ____| | \__\_
      _/__/!! | |__  | (___ | |       /  \  | |__) | |__  | | !!\__\_
    _/__/Run, |  __|  \___ \| |      / /\ \ |  ___/|  __| | | Run,\__\_
  _/__/alien, | |____ ____) | |____ / ____ \| |    | |____|_| alien,\__\_
 /__/run away |______|_____/ \_____/_/    \_\_|    |______(_) run away\__\
+----------------- PUR-80 BASIC GAME for Mattel Aquarius -----------------+
| (c) 2021 Nick Shcherbyna (Lviv, UA)     computer.history.lviv@gmail.com |
+-------------------------------------------------------------------------+
| Instructions /                                                          |
|--------------                                                           |
| You are an alien imprisoned in the underground concentration camp known |
| as HANGAR-18.  There are five levels with six floors each, patrolled by |
| bots.  You have to avoid sentinels, otherwise mission will restart from |
| scratch.  Fortunately bots are a bit dumb.  Run as fast as possible and |
| climb up on the ladders using [O]-left, [P]-right, [A]-up and [Z]-down. |
|                                                                         |
| Use real hardware or VirtualAquarius emulator:                          |
|                              https://www.zophar.net/download_file/32834
|                                                                         |
| Use either Util->Paste to copy the BASIC source from file, or CLOAD the |
| tape image using File->Play Cassette File... Then RUN the game program. |
|                                                                         |
+-------------------------------------------------------------------------+
| Source Code Explained /                                                 |
|-----------------------                                                  |
|                                                                         |
| Variables:                                                              |
| (X, Y) - Alien coordinates                                              |
| Z      - Alien address in VRAM                                          |
| B      - Saved character in place of alien                              |
| C      - Character below of alien                                       |
| (U, V) - Sentinel coordinates                                           |
| W      - Sentinel address in VRAM                                       |
| D      - Saved character in place of sentinel                           |
| E      - Character below of sentinel                                    |
| H      - Ladder character code                                          |
| M      - Floor character code                                           |
| S      - Current level minus 1                                          |
| K      - Shifted keycode                                                |
| R      - Random value                                                   |
| A$     - Beep character                                                 |
|                                                                         |
| Lines:                                                                  |
| 0 Init VRAM address (bottom right), randomize if (re)start, iterate all |
|   screen characters.                                                    |
| 1 Init variables for procedural generation: L for ladder, F for floor.  |
| 2 Calculate character and display it. Init alien and bot coordinates.   |
| 3 Calculate bot VRAM addr. Check for game over condition and restart.   |
| 4 Calculate alien VRAM addr. Put alien sprite, poll keyboard.           |
| 5 Determine new alien position. Check whether level is completed.       |
| 6 finalize new alien position. Start dealing with sentinel.             |
| 7 Put sentinel sprite, determine new vertical position.                 |
| 8 Determine new horizontal position. Delay, restore characters in place |
|   of sprites.                                                           |
| 9 Display message, end game if all levels completed.                    |
|                                                                         |
+-------------------------------------------------------------------------+
| Source Code Listing /                                                   |
|---------------------                                                    |
| Note: Microsoft BASIC in Mattel Aquarius limits line of code to just 72 |
|       characters, so the program below is effectively PUR-72 ;-)        |
|         111111111122222222223333333333444444444455555555556666666666777 |
|123456789012345678901234567890123456789012345678901234567890123456789012 |
|         |         |         |         |         |         |         |   |
|0A=13248:FORY=0TO24:FORX=1TO38:Z=YAND3:R=RND(2*(S=0)+X+Y):L=PEEK(A+X+40) |
|1H=172:M=134:L=Z=1ANDL=MANDC<>HANDR<.2ORZ<>1ANDL=H:F=Z=LAND(C=32ORR<.98) |
|2C=32-102*(Y=0ORF)-140*L:POKEA+X,C:NEXTX:A=A-40:NEXTY:U=38:V=4:X=1:Y=6*V |
|3W=A+40*V+U:A$=CHR$(7):IFX=UANDY=VTHENPOKEW,209:?A$;A$;A$;CHR$(11);:RUN! |
|4Z=A+40*Y+X:B=PEEK(Z):C=PEEK(Z+40):POKEZ,146+(X+YAND1):K=PEEK(14346)-111 |
|5X=X+(X>1ANDK=0ANDC>32)-(X<38ANDK=1ANDC>32):Y=Y+(B=HANDK=-14):IFY=0THEN9 |
|6Y=Y-(C=32ORC=HANDK=11)::D=PEEK(W)::E=PEEK(W+40)::F=14+5*(U+VAND-(E>32)) |
|7POKEW,F-11*(E=32):L=(V<YANDE<>MORE=32)-(V>YANDD=H):REM(c)NickShcherbyna |
|8U=U+(L=0)*SGN(U-X):V=V-L:FORI=5*STO50:NEXT:POKEZ,B:POKEW,D:GOTO3ESCAPE! |
|9S=S+1:?CHR$(11);"CONGRATS! Level";S;"/5 completed!";A$;A$;A$:IFS<5THEN0 |
|                                                                         |
+-------------------------------------------------------------------------+

14-те місце з 66 цілком достойне, з врахуванням фізичного обмеження 72 символи в рядку (тобто, на інших платформах було на 10% більше місця для коду):

► Показати

results.png

[Nick]

Остання гра у 2019-му (категорія PUR-120) отримала назву "Be Quick or Be Dead" — екстремальний клавіатурний тренажер, де або встигаєш натиснути потрібну клавішу, або помираєш від пострілу супротивника. Дія відбувається у часи Дикого Заходу, а в якості платформи обрано доволі екзотичний TRS-80 Model 100:

ScrShot1.png

ScrShot2.png

ScrShot3.png

ScrShot4.png

І знову cover art:

Cover.png

Код гри:

► Показати

Код: Виділити все

0POWERCONT:CLS:DEFINTC-Z:READA$:FORI=0TO99:?@54,"¨¾” BE QUICK":?@135,"OR BE DEAD":?@249,"« 2021 ";A$:IFINKEY$=""THENNEXT
1CLS:FORY=8TO55:READX,Z:IFZTHENY=Y+(X<0):X=ABS(X):LINE(40+X,Y)-(40+Z,Y):LINE(199-Z,Y)-(199-X,Y):NEXT:DATANick Shcherbyna
2FORI=0TO3:Y=Y+I:LINE(0,Y)-(239,Y):NEXT:R=97+26*RND(1):SOUNDX,R:A$=CHR$(R):?@11,"Press [";A$;"] to shoot":R=123*RND(123)
3FORI=RTO254:I=(IORINKEY$=A$)AND255:NEXT:I=I=255:P=59-121*I:FORY=29TO37STEP3:READR:LINE(P,Y)-(P+(I+1+I)*R,Y+2),1,BF:NEXT
4D=I+1+I:BEEP:FORC=1TO0STEP-1:FORR=37TO127STEP30:LINE(P+17*D,30)-(P+R*D,30),C:NEXT:NEXT:W=199+159*I:V=239*(1+I):RESTORE7
5FORY=8TO55:READX,Z:IFZTHENY=Y+(X<0):X=ABS(X):LINE(W-D*X,Y)-(W-D*Z,Y),0:LINE(V-D*Y,63)-(V-D*Y,63+(Z>11)*(Z-12)):NEXT:REM
6RESTORE7:?@96,"YOU ";MID$("DIEDWIN",4*I+5,4):PSET(P+17*D,9+20*RND(1)):PRESET(P+17*D,9+20*RND(1)):IFINKEY$=" "THEN1ELSE6
7DATA10,16,7,17,6,18,5,19,5,19,5,19,5,19,1,19,,24,1,25,5,24,5,20,5,20,6,20,6,19,7,19,7,18,6,17,5,16,3,18,2,19,2,19,1,19.
8DATA1,20,1,20,,6,-7,20,,6,-8,20,,5,-9,19,,5,-9,20,,5,-8,20,,6,-8,21,,21,,21,,21,1,20,3,19,5,12,-13,19,5,12,-13,19,4,11.
9DATA-13,19,4,11,-13,19,4,10,-13,19,4,10,-13,19,3,9,-13,19,3,9,-13,19,2,9,-13,20,2,8,-14,21,2,8,-15,21,2021,,16,10,4,120

Опис гри (англ.):

► Показати

                  ____  _____   ____  _     _  ____  _  __      MATURE 17+
                 /  __\/  __/  /  _ \/ \ /\/ \/   _\/ |/ /   .--------------.
   THE DEADLIEST | | //|  \    | / \|| | ||| ||  /  |   /    | ____    ____ |
   TYPING TUTOR! | |_\\|  /_   | \_\|| \_/|| ||  \__|   \    ||_   \  /   _||
                 \____/\____\  \____\\____/\_/\____/\_|\_\   |  |   \/   |  |
    ____  ____    ____  _____   ____  _____ ____  ____       |  | |\  /| |  |
   /  _ \/  __\  /  __\/  __/  /  _ \/  __//  _ \/  _ \      | _| |_\/_| |_ |
   | / \||  \/|  | | //|  \    | | \||  \  | / \|| | \| PUR  ||_____||_____||
   | \_/||    /  | |_\\|  /_   | |_/||  /_ | |-||| |_/| 120  |              |
   \____/\_/\_\  \____/\____\  \____/\____\\_/ \|\____/      '--------------'
                                                             INTENSE VIOLENCE
   BASIC game for Tandy TRS-80 Model 100/102                  BLOOD AND GORE

   (c) 2021 Nick Shcherbyna (Lviv, Ukraine)   computer.history.lviv@gmail.com

=< INSTRUCTIONS >===============================================================

Pretty standard situation for Wild West - two cowboys with guns are starting the
duel. Shoot first or die, be quick or be dead!
After signal a message "Press [?] to shoot" appears on the screen, with a random
lowercase letter shown. Strike the corresponding key immediately, otherwise your
opponent will shoot first and kill you. After shooting press [SPACE] to initiate
another duel.

You can use Virtual T emulator (http://sourceforge.net/projects/virtualt/). Copy
BQUICK.BA to Tandy's filesystem using File/Load file from HD, then pick it using
arrow keys and press [ENTER] to load and run the game. Press [Ctrl]+[C] to exit.
It is better to turn sound on: Emulation/Peripheral Setup.../Sound/Enable Sound.

=< SOURCE CODE EXPLAINED >======================================================

0 Disable sleeping. Clear screen. Display game title and copyright. Wait for any
  key or timeout.
1 Clear screen. Draw left and right (mirrored) cowboys.
2 Draw ground (3D projection). Pick random letter and show message after signal.
  Pick random timeout.
3 Wait for valid keypress or timeout. Determine who pulled a trigger first. Draw
  the gun.
4 Get shooting direction. Play sound. Animate the bullet.
5 Wipe the standing cowboy and draw a dead one simultaneously.
6 Print win/dead message. Animate the smoking gun until spacebar is pressed.
7 Cowboy image scanlines. Two values specify start and end coordinates. Negative
  start prevents incrementing the scanline (absolute value is used). Zero end is
  a stop mark.
8 Cowboy image scanlines, continued.
9 Cowboy image scanlines, continued. Signal frequency. Gun component widths.

================================================================================

І, нарешті, можна мене привітати — III місце в категорії!

► Показати

results.png

[Nick]

А у таких малих іграх, наприклад у останній, сам персонаж "сонік" це як він намальований? просто якийсь двохвимірний масив пікселів?

Трохи згодом я опишу прийоми програмування ігор на BASIC. Конкретно Сонік — це апаратний спрайт 16×16, опис якого займає 32 байти.