Українська спільнота компʼютерної історії • Конкурс BASIC 10 Liner Contest - Сторінка 2

Сторінка 2 з 3

Re: Конкурс BASIC 10 Liner Contest

Додано: 16 квітня 2023, 23:03

Nick

Конкурс має ще одну категорію "SCHAU" для неігрових програм, правила якої аналогічні EXTREME-256. Я подумав, якщо у 1978-му Даніель Бріклін придумав VisiCalc, чом би у 2021-му не перетворити його в 10 рядків коду на ZX BASIC?

ZXcel1.png

ZXcel2.png

ZXcel3.png

Коробкова версія у стилі Пітера Нортона:

Cover.png

Код програми (щиро дякую геніальному Стіву Вікерсу за VAL):

► Показати

Код: Виділити все

0DIM S$(10,20,9):DIM A(10,20):DIM T$(10,20,31):DIM C$(10,20,93):LET N$=S$(1,1):LET X=1:LET Y=1:LET Z=1:LET V=1:LET W=0:LET H=0:PAPER 7:INK 0:CLS:FOR J=1 TO 20:PRINT AT J,J<10;INK 1;J;:FOR I=1 TO 10:LET C$(I,J)="0":NEXT I:NEXT J:DEFFN D(A$)=A$>"/"AND":">A$
1DEFFN L(A$)="a"<=A$AND"{">A$:LET V$=CHR$176:PRINT AT 0,0;PAPER 6;"ZX";:RESTORE:RANDOMIZE USR 3438:FOR K=1 TO 7:READ A$,B$:PRINT#1;PAPER 6;INVERSE 1;A$;INVERSE 0;B$;:NEXT K:DATA"qaop","mov","x","cut","c","cpy","v","paste","w","view","0","-","7","clr",2021
2PRINT AT 21,0;T$(X,Y);:FOR I=Z TO Z+2:LET T=10*(I-Z):PRINT AT 0,T+7;INK 1;CHR$(I+64);:FOR J=1 TO 20:PRINT AT J,T+3;BRIGHT V AND(X=I OR Y=J);INVERSE V AND X=I AND Y=J;INK A(I,J);S$(I,J);:NEXT J:NEXT I::FOR K=0 TO 1:LET K$=INKEY$:LET K=LEN K$:NEXT K:GOTO 3
3LET L$="":LET Y=Y-(Y>1AND"q"=K$)+(Y<20AND"a"=K$):LET X=X-(X>1AND"o"=K$)+(X<10AND"p"=K$):LET Z=Z-(X<Z)+(X>Z+2):IF K$=CHR$ 13 THEN RANDOMIZE USR 3438:INPUT LINE L$:IF 31<LEN(L$)THEN CLS:FOR J=1 TO 20:PRINT AT J,J<10;INK 1;J;:NEXT J:LET L$="":REM<ZXcel/256>
4FOR K=1 TO"q"=K$OR"a"=K$OR"o"=K$OR"p"=K$:GOTO 2:NEXT K:IF""<L$THEN LET S$(X,Y)=L$:LET T$(X,Y)=L$:LET C$(X,Y)="0":LET F=1:FOR K=2 TO LEN(L$):LET F=F AND FN D(L$(K))OR"."=L$(K):NEXT K:IF F THEN LET C$(X,Y)=L$:LET A$=N$+L$:LET S$(X,Y)=A$(LEN A$-8 TO LEN A$)
5IF""<L$THEN IF"="=L$(1)THEN LET G$="":FOR K=2 TO LEN(L$)-1:LET A$=L$(K):LET I=CODE A$-64-(32 AND FN L(A$)):IF I>0 AND I<11 THEN LET K=K+1:LET T=K+FN D((L$+" ")(K+1)):LET J=VAL L$(K TO T):LET K=T:IF J>0AND21>J THEN LET A$=V$+""+"C$("+STR$ I+","+STR$ J+")"
6FOR L=1 TO"z"=K$AND NOT V:FOR J=1 TO 20:FOR I=Z TO Z+2:LPRINT S$(I,J);" ";:NEXT I:LPRINT:NEXT J:NEXT L::IF""<L$THEN RANDOMIZE USR 3438:PRINT#1;"Be patient ";:IF"="=L$(1)THEN LET G$=G$+A$:NEXT K:LET C$(X,Y)=G$+L$(K TO LEN(L$)):REM (c) 2021 Nick Shcherbyna
7LET G=1:LET F=CODE K$-48:LET F=F-A(X,Y)AND F>=0AND F<9:LET A(X,Y)=F+A(X,Y):IF""<L$THEN FOR I=1 TO 10:PRINT#1;INK 2;CHR$143;:FOR J=1 TO 20:FOR K=1 TO"="=T$(I,J,1):LET A$=STR$ VAL C$(I,J):LET A$=N$+A$:LET S$(I,J)=A$(LEN A$-8 TO LEN A$):NEXT K:NEXT J:NEXT I
8FOR L=1 TO"v"=K$AND W>0:LET L$="":LET M$=T$(W,H):FOR K=1 TO LEN(M$)-1:LET A$=M$(K):LET I=CODE A$-(32 AND FN L(A$)):IF""<M$AND"="=M$(1)AND I>64 AND I<76 THEN LET K=K+1:LET T=K+FN D((M$+" ")(K+1)):LET J=VAL M$(K TO T):LET K=T:LET A$=CHR$(I-W+X)+STR$(J-H+Y)
9LET L$=L$+A$:NEXT K:LET K$="":LET G=4:NEXT L:FOR K=1 TO"x"=K$OR"c"=K$:LET W=X:LET H=Y:NEXT K:FOR K=1 TO"x"=K$:LET S$(X,Y)=N$:LET T$(X,Y)="":LET C$(X,Y)="0":NEXT K:LET V=K$<>"w":GOTO G:REM In 1978 Dan Bricklin invented the interactive VISIble CALCulator..

Опис програми (англ.):

► Показати

       "In 1978 Dan Bricklin invented the interactive VISIble CALCulator.
        In 2021 I turned it into a BASIC 10-Liner."
                ____  _  _  ___  ____  __      _  ___   ___   _
               (_   )( \/ )/ __)( ___)(  )    / )(__ \ | __) / )
                / /_  )  (( (__  )__)  )(__  / /  / _/ |__ \/ _ \
               (____)(_/\_)\___)(____)(____)(_/  (____)(___/\___/

 (c) 2021 Nick Shcherbyna (Lviv, Ukraine)       computer.history.lviv@gmail.com

                                Category "SCHAU"

 INTRODUCTION:
 ZXcel/256, as one might guess, is a spreadsheet program written in ZX Spectrum
 BASIC. It supports strings and numbers, formulas, 8 colors, printing, and even
 copy/paste with automatic updating of references. There are 10x20 cells, named
 A1 to J20, with 3 visible columns (via horizontal scrolling).

 EMULATION:
 This software was developed and tested in BASINC Version 1.7. Download it at:
 https://arda.kisafilm.org/blog/?p=1230&lang=en
 Copy and paste line-by-line, or just File->Open... ZXCEL.BAS, then RUN. Tape
 image is also provided, use LOAD "" in any Speccy emulator.

 KEYS:
   [q]   - move the selection up
   [a]   - move the selection down
   [o]   - move the selection left
   [p]   - move the selection right
   [w]   - print preview mode (i.e., hide selection)
   [y]   - print using ZX Printer (from the preview)
   [0]   - pick the black color (default)
   [1]   - pick the blue color
   [2]   - pick the red color
   [3]   - pick the magenta color
   [4]   - pick the green color
   [5]   - pick the cyan color
   [6]   - pick the yellow color
   [7]   - pick the light gray color (i.e., hide cell)
   [x]   - clear the selected cell
   [c]   - copy from the selected cell
   [v]   - paste into the selected cell (and update references)
 [ENTER] - input a string/number/formula into the selected cell

 FORMULAS:
 Start formula with =. Integers and floating point numbers are supported. Cells
 are referred as A1, A2, ..., A20, B1, B2, ..., B20, ... ..., J1, J2, ..., J20.
 BASIC arithmetic operations are supported (+ - * / ^), e.g. =2*(A1+B1)+E5/100.
 Frozen references (e.g. $C$14, $B29, A$5) are NOT supported. Division by zero,
 recursive references (e.g. A1=2*B1+1, B1=C1/100, C1=A1+1.2), and syntax errors
 will crash the program!

 EXAMPLE:

         A           B           C           D           E
   +-----------+-----------+-----------+-----------+------
 1 | 1st Name  | Last Name | Salary, $ |         0 |
   +-----------+-----------+-----------+-----------+------
 2 | John      | Doe       |      3000 | =D1+C2    |
   +-----------+-----------+-----------+-----------+------
 3 | Nick      | Johnson   |      4500 | =D2+C3    |
   +-----------+-----------+-----------+-----------+------
 4 | Pam       | Cooper    |      3333 | =D3+C4    |
   +-----------+-----------+-----------+-----------+------
 5 |           |    Total: | =D4       |           |
   +-----------+-----------+-----------+-----------+------
 6 |           |           |           |           |

 will calculate

         A           B           C           D           E
   +-----------+-----------+-----------+-----------+------
 1 | 1st Name  | Last Name | Salary, $ |         0 |
   +-----------+-----------+-----------+-----------+------
 2 | John      | Doe       |      3000 |      3000 |
   +-----------+-----------+-----------+-----------+------
 3 | Nick      | Johnson   |      4500 |      7500 |
   +-----------+-----------+-----------+-----------+------
 4 | Pam       | Cooper    |      3333 |     10833 |
   +-----------+-----------+-----------+-----------+------
 5 |           |    Total: |     10833 |           |
   +-----------+-----------+-----------+-----------+------
 6 |           |           |           |           |

 Everything is calculated in the proper order. User can fill D2, copy it, then
 paste into D3 and D4, automatically obtaining the expected formulas.

 PRINCIPLE:
 A really exciting feature of ZX Spectrum BASIC, thanks to the genius of Steve
 Vickers, is its VAL() function. Today we would rather call it EVAL(), because
 unlike other versions that just convert the string argument into a number, it
 evaluates the BASIC expression. Moreover, the provided expression can contain
 another VAL(), and it will be computed first!
 Sounds like we have almost everything for our spreadsheet, just write the UI?
 Not so good. ZX BASIC requires variable initialization before use. While this
 is a good coding practice, LETting all cells preinitialized is a disaster for
 our very limited code space (I voluntary decided to support 10x20=200 cells).
 It will require almost 8 lines with 256 characters limit. In theory one would
 do that by POKEs to BASIC's system data structures, but this is a thin ice of
 nearly self-modified code (prohibited by the 10-Liner contest rules). Left it
 as an exercise to the reader.
 So we need an extra translation layer, call it ZXcel to BASIC compiler. Cells
 now are stored in the 2-dimentional array C$(10,20,93). Here 3rd dimension is
 not a typo, that is how ZX BASIC reserves the string space. The example above
 will compile into (parentheses are optional for single argument calls):

  C$      (1,         (2,          (3,                 (4,                (5,
     +-----------+-----------+-------------+-------------------------+-------
 ,1) |"0"        |"0"        |"0"          |"0"                      |
     +-----------+-----------+-------------+-------------------------+-------
 ,2) |"0"        |"0"        |"3000"       |"VAL C$(4,1)+VAL C$(3,2)"|
     +-----------+-----------+-------------+-------------------------+-------
 ,3) |"0"        |"0"        |"4500"       |"VAL C$(4,2)+VAL C$(3,3)"|
     +-----------+-----------+-------------+-------------------------+-------
 ,4) |"0"        |"0"        |"3333"       |"VAL C$(4,3)+VAL C$(3,4)"|
     +-----------+-----------+-------------+-------------------------+-------
 ,5) |"0"        |"0"        |"VAL C$(4,4)"|"0"                      |
     +-----------+-----------+-------------+-------------------------+-------
 ,6) |           |           |             |                         |

 RULES:
 - String is compiled into "0".
 - Number is compiled into its string representation.
 - Formula is tokenized and transformed. Each occurence of "A".."J" ("a".."j")
   followed by one or two digits is parsed into pair of indices (i,j) and then
   output as VAL C$(i,j). Other characters remain unchanged.

 EVALUATION:
 After any changes all cells with formulas are iterated sequentally and filled
 by VAL C$(i,j) result. While not optimal, it will produce the desired result,
 always performing full recursive evaluation. Optimization techniques found in
 professional spreadsheet software, such as topological sorting, require extra
 memory and code space.

 COPY/PASTE:
 Widespread spreadsheet software, such as Microsoft Excel or LibreOffice Calc,
 allows to copy the formula and paste it into another cell, with automatically
 updated references. For example, copying D2=D1+C2 and pasting it into D3 will
 emit D2+C3, while pasting it into D4 will produce D3+C4, etc. This definitely
 useful feature is implemented in ZXcel/256, except the frozen references that
 does not change (like $A$10).
 Assume we copy a formula from the cell (W,H), and paste it into (X,Y). To fix
 references we perform parsing, very similar to compilation process above, and
 replace each reference (I,J) as (I-W+X,J-H+Y).

 TRICKS:
 The THEN clause in an IF statement is executed until the end of line. This is
 undesirable. The scoped IF <cond> THEN ... ENDIF construct can be written as:
 FOR i=1 TO <cond> : ... : NEXT i.
 Comparsions in ZX BASIC produce 0 (FALSE) or 1 (TRUE), unlike MS BASIC, where
 TRUE is -1. The result of X AND Y is 0 if Y is zero, and X otherwise.
 The hidden power of VAL() is already explained above.

 LINES:
 0. Declare 2D array S$(10,20,9) for visible representation of cells.
    Declare 2D array A(10,20) for cell colors (zeroed, so black by default).
    Declare 2D array T$(10,20,31) for user INPUT strings (stored as is).
    Declare 2D array C$(10,20,93) for compiled cells (read PRINCIPLE above).
    Initialize N$ as an empty cell.
    (X,Y)=(1,1) is a selected cell, Z is horizontal scrolling position.
    Set visibility flag V (cleared for print preview).
    (W,H)=(0,0) is a copied cell (0 means not copied yet).
    Clear screen.
    Print row numbers, initialize compiled cells to 0.
    Define function D() that checks if argument is a digit.
 1. Define function L() that checks if argument is a lowercase letter.
    Initialize V$ to the VAL BASIC token (you cannot just write "VAL").
    Put "ZX" at the left top corner.
    Clear lines 22 and 23 (USR 3438 is a documented entrypoint).
    Print keyboard tips.
 2. Print the current cell content (as previously INPUTted by user).
    Iterate visible cells (I,J) to redraw. Also print column names.
    Wait for keypress and store the code into K$.
 3. Assume there is no input in L$.
    Change the selection row (Y) if [q] or [a] is pressed.
    Change the selection column (X) if [o] or [p] is pressed.
    Change the scrolling position (Z) if needed.
    If [ENTER] is pressed:
    - clear lines 22 and 23 (USR 3438 is a documented entrypoint);
    - INPUT the current cell content into L$;
    - redraw stuff from (0) and clear L$ if length exceeded the limit.
 4. Fast path for navigation keys, skip to (2).
    If there was user input in L$, assume string and initialize ?(X,Y) for S$,
    T$, and C$.
    Detect a number (should start with "+", "-", or digit, followed by digits
    and dots). If so, store the value into C$ and align right in S$.
 5. Skip if not a formula. Otherwise G$ will collect the compiled code. Refer
    to RULES above for details on parsing and compilation.
 6. Handle LPRINTing if [z] is pressed and print preview (V=0). Otherwise, if
    there was user input:
    - clear lines 22 and 23 (USR 3438 is a documented entrypoint);
    - show the "Be patient" message there;
    - if we compile, append the new output and return to (5). Append the last
      character if it was not parsed.
 7. Set the return line G to (1).
    Change the current cell color A(X,Y) if [0]-[7] is pressed.
    If there was any input, recalculate the whole spreadsheet. See EVALUATION
    above. Results in S$ are aligned right, like in (4).
 8. If [v] is pressed, and stuff was copied (W>0), perform paste as described
    above in COPY/PASTE. M$ is the source string, number, or formula. L$ will
    contain the result.
 9. Finish pasting, set return line G to (4) and clear the keycode K$. Handle
    copy if [c] is pressed, delete if [x] is pressed. Set the visibility flag
    V unless [w] is pressed. Return to (1) normally, or to (4) for simulating
    INPUT L$.

 CONCLUSION:
 The project goal was to verify the theory that a decent spreadsheet software
 can be created on ZX Spectrum with a help of its amazing VAL(). It generally
 succeeded. With a help of machine code one can create something as useful as
 Microsoft Excel or LibreOffice Calc.
 It was an one day hobby project, so there is a lot to improve. Left it as an
 exercise to the reader.

І ця моя робота нарешті вразила поважне журі — I місце!

► Показати

Попереду був 2022-й і зовсім інші ігри...

Re: Конкурс BASIC 10 Liner Contest

Додано: 16 квітня 2023, 23:06

monoxrom

Мені дуже коробочка від софтини сподобалась!
Я б такий софт і прикупив))) Пора робити з ігрового спектрума, офісний пк!

Re: Конкурс BASIC 10 Liner Contest

Додано: 17 квітня 2023, 08:29

Nick

Конкурс традиційно проходив на початку весни (26.03.2002—9.04.2002). Але через навалу московитів було зовсім не до ігор на BASIC. Втім, кремлівська наволоч власне і добивалася руйнації звичного життя мільйонів українців, тож у певний момент я вирішив прийняти участь у конкурсі (категорія EXTREME-256 для платформи MSX). Гру NLAW, яка мала нести не лише розважальну функцію, писав під час повітряних тривог, коли крилаті ракети московитів падали на наші міста, в тому числі й на стародавній Львів. Військовослужбовець у траншеї має зупинити навалу танкової роти москалів. Після використання протитанкової ракети треба взяти іншу з верхнього чи нижнього краю траншеї, і так до знищення всіх танків противника. Кожен наступний танковий взвод рухається швидше за попередній, наприкінці гри треба знищити командирську машину:

NLAW.png

Можете пограти прямо зараз.
Код гри:

► Показати

Опис гри (англ.):

► Показати

███╗  ██╗██╗      █████╗  ██╗       ██╗     A MSX2 BASIC GAME
████╗ ██║██║     ██╔══██╗ ██║  ██╗  ██║
██╔██╗██║██║     ███████║ ╚██╗████╗██╔╝     by Nick Shcherbyna
██║╚████║██║     ██╔══██║  ████╔═████║      (Museum of Computer Technology)
██║ ╚███║███████╗██║  ██║  ╚██╔╝ ╚██╔╝      Lviv, Ukraine
╚═╝  ╚══╝╚══════╝╚═╝  ╚═╝   ╚═╝   ╚═╝





┌─────────┐
│ PREFACE ├────────────────────────────────────────────────────────────────────
└─────────┘
Being an Ukrainian, I was uncertain about the participation in this year's
BASIC  10-liner  Contest. While my city of Lviv is considered safe at this
moment, there are several air raid sirens per day, and four russian cruise
missiles hit some facility in the past days.
However, no kremlin's bastard can dictate my schedule, so let me submit an
EXTREME-256 game for MSX2/MSX2+/Turbo R, called NLAW. I dedicate this game
to brave Ukrainian soldiers who are defending our freedom.

┌──────────────┐
│ INSTRUCTIONS ├───────────────────────────────────────────────────────────────
└──────────────┘
The Next Generation Light Antitank Weapon is a fire-and-forget, lightweight
shoulder-fired disposable (single-shot) missile system, designed for use by
infantry.  The missile is guided by calculation based on  Predicted Line of
Sight,  and can carry  Out a Top Attack  or  Direct Attack  on an  armoured
vehicle. NLAW has its origins in a joint British–Swedish project.  Today it
is widely used by Ukrainian army fighting against the russian offensive.
You are a brave Ukrainian soldier of Territorial Defense Forces,  seeing an
approaching russian tank battalion of "kantemirovskaya" Division. Good news
are that they are out of ammo (supply chains were destroyed by Ukrainians),
and you have got a lot of NLAWs in your trench. Take NLAW from either side,
aim, fire, and repeat again until the last na[Z]i tank is burned out!  Next
tank company moves faster than the previous.
Controls: [↑] — move up, [↓] — move down, [SPACE] — fire.
You can use the online emulator https://webmsx.org/ to play. Select Machine
in Settings (MSX Turbo R for faster gameplay),  copy the code to clipboard,
press [Alt]-[V] and [Ctrl]-[V]. Finally press [F5] to RUN.

┌─────────┐
│ SPRITES ├────────────────────────────────────────────────────────────────────
└─────────┘
Sprite size is 16×16 pixels, russian T-90 tank is made of 4 sprites. Sprite
sheet is shown below:

         0                  1                   2                  3
   
   
   
   
   
   
   
   
   
   
   
   
   
   
   
   
         4                  5                   6                  7
   
   
   
   
   
   
   
   
   
   
   
   
   
   
   
   
         8                  9                  10                 11
   
   
   
   
   
   
   
   
   
   
   
   
   
   
   
   
        12                 13                  14                 15
   
   
   
   
   
   
   
   
   
   
   
   
   
   
   
   

There are 16 sprites, 32 bytes each. This requires more than 6 lines of code,
leaving almost no space for the game code:

0DATA0,0,0,0,255,255,0,0,0,0,0,0,0,0,0,0,0,0,0,0,239,239,0,0,0,0,0,0,0,0,0,0,0,
0,0,0,127,127,0,1,127,255,127,63,23,15,7,3,7,0,0,3,247,247,5,255,255,255,255,25
5,158,158,12,255,255,3,119,239,223,191,80,254,253,251,240,255,121,121,48,255,8,
200,255,221,221
1DATA255,85,255,255,255,127,255,231,231,195,255,0,0,224,192,176,48,0,255,255,25
5,255,255,158,159,14,252,0,0,0,0,0,6,15,239,246,248,240,192,128,0,0,0,1,3,2,2,7
,15,31,27,3,2,3,7,7,7,14,14,192,224,32,40,112,248,252,252,236,172,240,240,120,5
6,0,0,1,3,2,2,7
2DATA15,31,31,27,26,7,7,15,14,0,0,192,224,32,40,112,248,252,236,224,160,224,240
,112,112,56,56,1,3,58,70,187,187,187,71,59,2,3,7,7,7,14,14,192,224,32,40,112,24
8,252,252,236,172,240,240,120,56,0,0,1,3,58,70,187,187,187,71,59,2,7,7,15,14,0,
0,192,224,32,40
3DATA112,248,252,236,224,160,224,240,112,112,56,56,3,7,7,23,12,23,59,61,55,52,1
5,15,30,28,0,0,128,192,192,192,96,240,248,216,192,64,192,224,224,224,112,112,3,
7,7,23,12,23,59,53,7,4,7,15,14,14,28,28,128,192,192,192,96,240,248,248,216,88,2
24,224,240,112,0
4DATA0,3,7,7,23,12,23,59,61,55,52,15,15,30,28,0,0,128,192,220,254,119,235,247,2
54,220,64,192,224,224,224,112,112,3,7,7,23,12,23,59,53,7,4,7,15,14,14,28,28,128
,192,220,254,119,235,247,254,220,64,224,224,240,112,0,0,3,7,7,6,14,27,27,27,15,
7,7,7,15,62,60,48
5DATA128,192,64,32,68,252,255,244,248,88,192,224,240,112,56,56,0,0,0,224,159,24
5,253,255,224,0,0,0,0,0,0,0,0,0,6,57,247,31,255,255,15,6,0,0,0,0,0,0,3,7,7,230,
159,245,253,255,239,7,7,7,15,62,60,48,128,192,70,57,247,63,255,255,207,70,192,2
24,240,112,56,56
6DATA0,0,0,98,127,128,255,127,98,0,0,0,0,0,0,0,0,0,0,0,254,41,255,254,0,0,0,0,0
,0,0,0

The first optimization is getting rid of 0s, since MSX BASIC allows empty DATA
instead:

0DATA,,,,255,255,,,,,,,,,,,,,,,239,239,,,,,,,,,,,,,,,127,127,,1,127,255,127,63,
23,15,7,3,7,,,3,247,247,5,255,255,255,255,255,158,158,12,255,255,3,119,239,223,
191,80,254,253,251,240,255,121,121,48,255,8,200,255,221,221,255,85,255,255,255,
127,255,231,231
1DATA195,255,,,224,192,176,48,,255,255,255,255,255,158,159,14,252,,,,,,6,15,239
,246,248,240,192,128,,,,1,3,2,2,7,15,31,27,3,2,3,7,7,7,14,14,192,224,32,40,112,
248,252,252,236,172,240,240,120,56,,,1,3,2,2,7,15,31,31,27,26,7,7,15,14,,,192,2
24,32,40,112,248
2DATA252,236,224,160,224,240,112,112,56,56,1,3,58,70,187,187,187,71,59,2,3,7,7,
7,14,14,192,224,32,40,112,248,252,252,236,172,240,240,120,56,,,1,3,58,70,187,18
7,187,71,59,2,7,7,15,14,,,192,224,32,40,112,248,252,236,224,160,224,240,112,112
,56,56,3,7,7,23
3DATA12,23,59,61,55,52,15,15,30,28,,,128,192,192,192,96,240,248,216,192,64,192,
224,224,224,112,112,3,7,7,23,12,23,59,53,7,4,7,15,14,14,28,28,128,192,192,192,9
6,240,248,248,216,88,224,224,240,112,,,3,7,7,23,12,23,59,61,55,52,15,15,30,28,,
,128,192,220,254
4DATA119,235,247,254,220,64,192,224,224,224,112,112,3,7,7,23,12,23,59,53,7,4,7,
15,14,14,28,28,128,192,220,254,119,235,247,254,220,64,224,224,240,112,,,3,7,7,6
,14,27,27,27,15,7,7,7,15,62,60,48,128,192,64,32,68,252,255,244,248,88,192,224,2
40,112,56,56,,,
5DATA224,159,245,253,255,224,,,,,,,,,,6,57,247,31,255,255,15,6,,,,,,,3,7,7,230,
159,245,253,255,239,7,7,7,15,62,60,48,128,192,70,57,247,63,255,255,207,70,192,2
24,240,112,56,56,,,,98,127,128,255,127,98,,,,,,,,,,,,254,41,255,254,,,,,,,,

Now six lines — still not a plenty of code space. We need a small compression
algorithm. Consider the left top corner of the first sprite:

   0       0
   0       0
   0       0
   0       0
 255     239
 255     239
   0       0
   0       0
   0       0
   0       0
   0       0
   0       0
   0       0
   0       0
   0       0
   0       0

It seems perfect for RLE encoding: 4×0, 2×255, 14×0, 2×239, 10×0. We will
encode data as:

256 * (count - 1) + value

giving 768,511,3328,495,2304.

It is clear that many sprites differ only in details, notably the Ukrainian
soldier:

Previous      Current
   1 
   3 
   2 
   2 
   7 
  15 
  31 
sprite #4     sprite #5

If some bytes match to the corresponding ones in the previous sprite, we encode
data as:

-(count - 1)

giving -6.

Using the above technique, our sprite sheet transforms into:

0DATA768,511,3328,495,2304,-3,383,,1,127,255,127,63,23,15,7,3,7,-1,3,503,5,1279
,414,12,255,255,3,119,239,223,191,80,254,253,251,240,255,377,48,255,8,200,255,4
77,255,85,-2,127,255,487,195,255,256,224,192,176,48,,1279,158,159,14,252,1024,6
,15,239,246,248
1DATA240,192,128,512,1,3,258,7,15,31,27,3,2,3,519,270,192,224,32,40,112,248,508
,236,172,496,120,56,-1,-6,31,27,26,263,15,14,256,-6,236,224,160,224,240,368,312
,-1,58,70,699,71,59,2,3,519,270,-6,252,236,172,496,120,56,256,-9,263,15,14,256,
-6,236,224,160
2DATA224,240,368,312,3,263,23,12,23,59,61,55,52,271,30,28,-1,128,704,96,240,248
,216,192,64,192,736,368,-6,53,7,4,7,15,270,284,-6,248,216,88,480,240,112,256,-6
,61,55,52,271,30,28,256,-1,220,254,119,235,247,254,220,64,192,736,368,-6,53,7,4
,7,15,270,284,-9
3DATA480,240,112,256,-2,6,14,539,15,519,15,62,60,48,-1,64,32,68,252,255,244,248
,88,192,-2,312,512,224,159,245,253,255,224,2048,6,57,247,31,511,15,6,1280,3,263
,230,-3,239,519,15,62,60,48,128,192,70,-1,63,-1,207,70,192,224,240,112,312,512,
98,127,128,255
4DATA127,98,2560,254,41,255,254,1792

That is slightly more than 4 lines. The purified decoder is:

0DEFINTA-Y:FORI=0TO15:S$="":FORJ=1TO32:READN:IFN<0THENN=-N:S$=S$+MID$(SPRITE$(I
-1),J,N+1)ELSEV=NAND255:N=N/256:S$=S$+STRING$(N+1,V)
1J=J+N:NEXTJ:SPRITE$(I)=S$:NEXT

162 characters in total, so we saved about two lines for the meaningful code!

┌─────────┐
│ LISTING ├────────────────────────────────────────────────────────────────────
└─────────┘
0DEFINTA-Y:D=0:T=0:SOUND7,0:COLOR3,1,1:SCREEN5,2:CLS:READT$,U$,V$:OPEN"GRP:"AS1
:PSET(112,92),0:?#1,T$:FORI=0TO15:S$="":FORJ=1TO32:READN:PSET(ABS(N),12*I),12:I
FN<0THENN=-N:S$=S$+MID$(SPRITE$(I-1),J,N+1)ELSEV=NAND255:N=N/256:S$=S$+STRING$(
N+1,V):DATANLAW::
1J=J+N:NEXTJ:SPRITE$(I)=S$:Z=I*ATN(1)/8:M=20*SIN(Z):FORJ=16*COS(Z)TO191STEP5+N:
PSET(M,J),12:NEXT:NEXTI:PSET(112,92),0:COLOR1:?#1,T$:PUTSPRITE8,(0,0),3,13:PUTS
PRITE9,(0,176),3,13:FORI=1TO5:READM,N,F,C:LINE(M,N)-(M+11,N+F),C,BF:NEXT:C=3:N=
0:P=88:X=255:Y=P:
2J=STICK(0):F=(PAND4)=0:PUTSPRITE4,(0,P),C,12+(8+F)*(J=5)-N+(4+F)*(J=1)-N:P=P+4
*(J=1ANDP>0)-4*(J=5ANDP<176):N=(NORP=0ORP=176)ANDD<16:PUTSPRITE5,(D,M),14ANDD>0
,15:SOUND8,D>0AND7:D=D>0AND(D+8)AND255:M=M+(D>=16ANDD<=112):IFSTRIG(0)ANDNANDD=
0THENN=0:M=P:D=8:
3I=X:FORJ=0TO3:K=I<=255ANDI>=-32:PUTSPRITEJ,(I,Y),-K-K,J:I=I+16:NEXT:PSET(X+32,
Y+15+2*RND(1)),-12*(RND(1)>.5):X=X-T/10-1:F=X>-16ORABS(Y-P)>8:C=CANDF:IFX<-64TH
ENPLAYU$:FORJ=0TO1:FORI=193TO198:LINE(2,I)-(13,I),POINT(242,I):NEXT:J=-STRIG(0)
:NEXT:RUN:'Glory:
4IFD<X+29ORD>X+51ORM<Y-12ORM>YTHEN2ELSEPUTSPRITE5,,0:FORR=0TO15:CIRCLE(D+8,M+6)
,R,8:SOUND8,R:NEXT:FORR=15TO0STEP-1:J=RAND3:PUTSPRITEJ,(16*J+X,Y),R/4+8,J:CIRCL
E(D+8,M+6),R,1:NEXT:D=0:X=255:Y=160*RND(1)+16:T=T+1:LINE(35,193)-(6*T+35,198),8
,BF:IFT<31THEN 2:
5PLAYV$:FORJ=0TO3:PUTSPRITEJ,,0,J:NEXT:FORJ=0TO1:FORI=193TO198:LINE(242,I)-(253
,I),POINT(2,I):NEXT:J=-STRIG(0):NEXT:RUN:DATAV15L8GEL4AL2E,V15L8CL4FEGL8CFGABL4
C5L8F,768,511,3328,495,2304,-3,383,,1,127,255,127,63,23,15,7,3,7,-1,3,503,5,127
9,414,12,255:'UA:
6:DATA255,3,119,239,223,191,80,254,253,251,240,255,377,48,255,8,200,255,477,255
,85,-2,127,255,487,195,255,256,224,192,176,48,,1279,158,159,14,252,1024,6,15,23
9,246,248,240,192,128,512,1,3,258,7,15,31,27,3,2,3,519,270,192,224,32,40,112,24
8,508,236,172,496
7DATA120,56,-1,-6,31,27,26,263,15,14,256,-6,236,224,160,224,240,368,312,-1,58,7
0,699,71,59,2,3,519,270,-6,252,236,172,496,120,56,256,-9,263,15,14,256,-6,236,2
24,160,224,240,368,312,3,263,23,12,23,59,61,55,52,271,30,28,-1,128,704,96,240,2
48,216,192,64,192
8:DATA736,368,-6,53,7,4,7,15,270,284,-6,248,216,88,480,240,112,256,-6,61,55,52,
271,30,28,256,-1,220,254,119,235,247,254,220,64,192,736,368,-6,53,7,4,7,15,270,
284,-9,480,240,112,256,-2,6,14,539,15,519,15,62,60,48,-1,64,32,68,252,255,244,2
48,88,192,-2,312:
9:DATA512,224,159,245,253,255,224,2048,6,57,247,31,511,15,6,1280,3,263,230,-3,2
39,519,15,62,60,48,128,192,70,-1,63,-1,207,70,192,224,240,112,312,512,98,127,12
8,255,127,98,2560,254,41,255,254,1792,2,193,2,5,2,196,2,11,242,193,1,15,242,195
,1,4,242,197,1,8:

┌─────────────┐
│ EXPLANATION ├────────────────────────────────────────────────────────────────
└─────────────┘
Line 0: Screen and variable setup. Sprite decoder (described above) intermixed
with the field drawing code, see PSET. D is the horizontal missile coordinate,
T is the number of tanks destroyed.
Line 1: Sprite decoder (described above) intermixed with the trench drawing
code, see PSET. Draw both NLAW supplies. Draw Ukrainian and russian flags.
Initialize variables. C is the player color/visibility, N is the NLAW flag, P
is the player's vertical coordinate, X and Y are tank coordinates.
Line 2: Poll joystick (i.e., arrow keys). F is the player step. Draw the player
sprite according to direction, step, and NLAW presence. Modify the player
position. Draw the missile sprite (transparent if not launched). Play the sound
effect. Modify NLAW coordinates D and M. Poll the button (i.e., space bar).
Launch the missile if allowed.
Line 3: Draw the T-90 tank (4 sprites) and its trail (see PSET). Modify the
tank's position. F is the tank/player collision, hide the player if so. If the
left side is approached then play the Game Over music, replace the Ukrainian
flag, and wait until [SPACE] is pressed, then restart.
Line 4: Loop to 2 if tank is not hit by the missile. Otherwise hide the
missile, draw the explosion (see CIRCLE), and play the sound effect. Burn the
tank (i.e., change colors in a loop). Initialize next tank's coordinates.
Update the progress bar, loop to 2 if there are tanks left.
Line 5: Play the Victory march music, raise the Ukrainian flag, and wait until
[SPACE] is pressed, then restart. DATA for Game Over and Victory music. Sprites
(begin).
Line 6: Sprites (continue).
Line 7: Sprites (continue).
Line 8: Sprites (continue).
Line 9: Sprites (end). Ukrainian and russian flag stripes (starting 2,193,2,5)
— x, y, height - 1, color.

───────────────────────────────────────────────────────────────────────────────

Програма отримала призове II місце, а також зіграла свою інформаційну роль — член журі не міг стримати емоцій під час гри.

► Показати

Слава Україні!

Героям слава!

Конкурс BASIC 10 Liner Contest

Додано: 17 квітня 2023, 09:46

Nick

Всю зиму 2022-2023 московити обстрілювали енергетичну інфраструктуру, намагаючись поставити наш нарід на коліна. Завдяки їх потугам мені довелося не один раз запускати інверторний генератор, втім особливих незручностей кремлівська наволоч не завдала в першу чергу завдяки філігранній роботі українських сил ППО. Тому сюжет наступної гри був наперед визначений: NASAMS defends Ukraine, а реалізовано її було в категорії EXTREME-256 для платформи MSX:

SCRSHOT1.PNG

SCRSHOT2.PNG

SCRSHOT3.PNG

SCRSHOT4.PNG

Можете пограти прямо зараз.
Код гри:

► Показати

Опис гри (англ.):

► Показати

'     _   _____   _____ ___    __  ________        __     ____               __        __  ____              _
'    / | / /   | / ___//   |  /  |/  / ___/   ____/ /__  / __/__  ____  ____/ /____   / / / / /___________ _(_)___  ___
'   /  |/ / /| | \__ \/ /| | / /|_/ /\__ \   / __  / _ \/ /_/ _ \/ __ \/ __  / ___/  / / / / //_/ ___/ __ `/ / __ \/ _ \
'  / /|  / ___ |___/ / ___ |/ /  / /___/ /  / /_/ /  __/ __/  __/ / / / /_/ (__  )  / /_/ / ,< / /  / /_/ / / / / /  __/
' /_/ |_/_/  |_/____/_/  |_/_/  /_//____/   \__,_/\___/_/  \___/_/ /_/\__,_/____/   \____/_/|_/_/   \__,_/_/_/ /_/\___/
'
' EXTREME-256 BASIC 10-liner for MSX            (C) 2023 Nick Shcherbyna - Museum Of Computer Technology - Lviv, Ukraine |.
                                                                                                                         \ \
' One year of full-scale russian invasion to Ukraine have passed. Brave Ukrainian forces stopped their evil legions, but  \ \
' the terrorist state continues air attacks using various sorts of drones and missiles. Fortunately, Western allies gave   \ \-
' some powerful air-defence systems, so with your professionalism and some luck peaceful Ukrainian cities will survive.    |\`\
'     NASAMS (Norwegian Advanced Surface to Air Missile System) is a distributed and networked medium to long range          \ \            |||
'     air-defence system.  The missile has a range of up to 25 km.                                                            \ \-          '0'####   ###
'     The system integrates US-built AN/TPQ-36A LASR (Low Altitude Surveillance RADAR) 3D radars and AIM-120 AMRAAM           |\`            |#############
'     missiles with an indigenously developed BMC4I system called Fire Distribution Center.  The FDC connected to a              @@          |##############
'     TPQ-36A radar forms an "Acquisition Radar and Control System" (ARCS).                                               ___ ___@@@_        |#::::###:::###
' Player controls three NASAMS Multi-Missile Launchers by pressing [ 1 ]..[ 4 ], numbered according to location (left to  |_^ |_^ |@@ |\     |::::::::::::::
' right). Key corresponding to the AN/TPQ-36A does nothing. System is deployed in distinct configuration for each level.  \__\\__\\__\| \    |:    :::   :::
'     There are three levels, where russians launch different stuff:                                                      |_^ |_^ |_^ |\ \   |             :
'     1) EASY   - HESA Shahed 136 drone (aka Geran-2);                                                                    \__\\__\\__\| \ \  |
'     2) MEDIUM - 3M54-1 Kalibr cruise missile;                                                                            \   \   \   \ O|  |
'     3) HARD   - 9M723 Iskander-M quasi-ballistic missile.                                                                 \===\---\===\ |  |
'     Next level is opened after destroying 10 enemy objects.  When a russian object is intercepted, score is increased.     \()|===|\___\|  |
'     Otherwise score is decreased, and game is over when it drops below zero.                                               / /[__]|_\  |   |
' You can try the game in different MSX emulators, e.g. https://webmsx.org/                                                |/____________||  |
' For WebMSX, copy the BASIC code to clipboard, press [ Alt ]-[ V ] and [ Ctrl ]-[ V ], then press [ F5 ] to start.        ||____________|| /_\
' Or just open the URL from NASAMS.URL. Glory to Ukraine!

'___5___10___15___20___25___30___35___40___45___50___55___60___65___70___75___80___85___90___95__100__105__110__115__120__125__130__135__140__145__150__155__160__165__170__175__180__185__190__195__200__205__210__215__220__225__230__235__240__245__250__255
0DEFINTA-Z:SCREEN2,2,0:OPEN"GRP:"AS#1:G=0:L=0:Q=0:DIMM(3):DEFFNR(V,S,M)=V/SANDMOR(VANDM)*S:FORI=0TO3:A$="":B$="":FORJ=0TO15:READK,Z:A$=A$+STRING$(K+1,Z):B$=B$+STRING$(K+1,FNR(FNR(FNR(Z,2,85),4,51),16,15)):J=J+K:NEXT:SPRITE$(I)=A$+B$:NEXT:ONSPRITEGOSUB8
' Variables:
' G   - air raid siren frequency;
' L   - level (1..3), 0 for title screen;
' Q   - score;
' M() - number of missiles per launcher.
' Functions:
' FNR() - helper function for horizontal mirroring of sprite, see https://graphics.stanford.edu/~seander/ ... seParallel
' All sprites are horizontally symmetrical:
' SPRITE$(0) - our SL-AMRAAM surface-to-air missile;
' SPRITE$(1) - HESA Shahed 136/Geran-2 drone;
' SPRITE$(2) - 3M54-1 Kalibr cruise missile;
' SPRITE$(3) - 9M723 Iskander-M quasi-ballistic missile.

'___5___10___15___20___25___30___35___40___45___50___55___60___65___70___75___80___85___90___95__100__105__110__115__120__125__130__135__140__145__150__155__160__165__170__175__180__185__190__195__200__205__210__215__220__225__230__235__240__245__250__255
1N=0:S=0:T=1:U=3:Y=-32:Z=209:COLOR12,7,1:CLS:LINE(0,160)-(255,191),10,BF:FORP=0TO3:M(P)=6:GOSUB6:IFL=0THENREADA$:PRESET(128-4*LEN(A$),9*P+62):COLOR2+P:PRINT#1,A$:NEXTELSENEXT:COLOR4,10:PRESET(0,184):PRINT#1,"Score";Q;:PRESET(200,184):PRINT#1,"Level";L;
' Variables:
' N - number of intercepted enemy objects;
' S - rotation angle of AN/TPQ-36A LASR 3D radar (0 is 0|180, 7 is 180|360 deg.);
' T - rotation angle of AN/TPQ-36A radar (1 for 0..180, -1 for 180..360);
' U - green shade of radar surface (3 for angles 0..180, 12 for angles 180..360);
' X - x-coordinate of SL-AMRAAM (not initialized here);
' Y - y-coordinate of SL-AMRAAM;
' V - x-coordinate of enemy object (not initialized here);
' Z - y-coordinate of enemy object.
' - Draw ground;
' - in a loop on variable P (0..3):
'   - Initialize the number of missiles per launcher;
'   - Draw NASAMS Multi-Missile Launcher or AN/TPQ-36A radar by subroutine 6;
'   - Put text (title, "YOU WIN" or "GAME OVER", depending on current DATA pointer);
' - Draw current score and level.

'___5___10___15___20___25___30___35___40___45___50___55___60___65___70___75___80___85___90___95__100__105__110__115__120__125__130__135__140__145__150__155__160__165__170__175__180__185__190__195__200__205__210__215__220__225__230__235__240__245__250__255
2IFL=0ANDK$=" "ORN>9THENPUTSPRITE0,(0,208):IFL=3THENREADA$,A$,A$:GOTO7ELSEL=L+1:GOTO1ELSEK$=INKEY$:R=80*L:IFM(L)>0THENLINE(R+S+1,160)-(R+14-S,174),U,BF:LINE(R,160)-(R+S,174),10,BF:LINE(R+15-S,160)-(R+15,174),10,BF:S=S+T:IFS=0ORS=7THENT=-T:IFSTHENU=15-U
' - Conditionally switch to the next level;
' - If level 3 completed, skip "GAME OVER" message and go to 7;
' - Poll keyboard;
' - If AN/TPQ-36A radar is alive, rotate it.

'___5___10___15___20___25___30___35___40___45___50___55___60___65___70___75___80___85___90___95__100__105__110__115__120__125__130__135__140__145__150__155__160__165__170__175__180__185__190__195__200__205__210__215__220__225__230__235__240__245__250__255
3PUTSPRITE0,(X,Y),15,0:X=X-4*(Z>0)*SGN(V-X):IFY>-32ANDY<ZANDY<96THENY=-32ELSEIFY>-32THENY=Y-4ELSEP=VAL(K$)-1:IFP>=0ANDP<4THENIFP<>LANDM(P)>0THENM(P)=M(P)-1:GOSUB9:X=80*P:Y=144:RESTORE8:FORI=0TO4:READA,B:SOUNDA,B:NEXT:'DedicatedToMyFriendVegardSkjefstad
' - Put the SL-AMRAAM missile;
' - Adjust its x position to lock on target;
' - Adjust its y position if launched, launch if the corresponding key pressed (redraw the launcher with one more empty slot, play sound effect).

'___5___10___15___20___25___30___35___40___45___50___55___60___65___70___75___80___85___90___95__100__105__110__115__120__125__130__135__140__145__150__155__160__165__170__175__180__185__190__195__200__205__210__215__220__225__230__235__240__245__250__255
4SOUND4,192+G:G=(G+2)AND63:SOUND10,7-G/16:SOUND7,179ORL=0AND12:PUTSPRITE1,(V,Z),6,L:IFZ<160THENZ=Z+2*LELSEW=V-(Z=209):GOSUB8:PUTSPRITE1,(V,Z):IFQ<0THEN7ELSEV=16*INT(15*RND(1)):Z=-32:SPRITEON:IFWMOD80=0THENM(W/80)=0:IFM(0)+M(1)+M(2)+M(3)=0THENQ=-1:GOTO7
' - Play air raid siren sound;
' - Put an enemy object;
' - Adjust its y position or explode if ground is reached (decrement score, game is over if negative, initialize new object position, delete all missiles in M() if launcher is hit).

'___5___10___15___20___25___30___35___40___45___50___55___60___65___70___75___80___85___90___95__100__105__110__115__120__125__130__135__140__145__150__155__160__165__170__175__180__185__190__195__200__205__210__215__220__225__230__235__240__245__250__255
5IFK$<>CHR$(27)THEN2ELSESOUND7,191:END:DATA5,1,,3,,7,5,1,,3,,7,,7,,128,1,255,,127,,63,,31,,15,,7,5,3,,1,,15,,7,4,3,1,63,5,3,,1,,31,,15,5,7,5,3,1,1,*NASAMS* defends Ukraine,(C) 2023 Nick Shcherbyna,"Keys: [1]-[4] Fire, [Esc] Quit",Press [SPACE] to start
' - End game if [Esc] was pressed.
' DATA:
' - Sprites (SL-AMRAAM, Shahed 136, Kalibr, Iskander-M);
' - Title text.

'___5___10___15___20___25___30___35___40___45___50___55___60___65___70___75___80___85___90___95__100__105__110__115__120__125__130__135__140__145__150__155__160__165__170__175__180__185__190__195__200__205__210__215__220__225__230__235__240__245__250__255
6IFP=3THEN9ELSE:I=80*P+24:A=8+8*((P+L)MOD2):FORJ=ITOI+40STEPA:K=170-(J*L+J+P*L)MOD9:C=9+6*(KMOD2):LINE(J+KMOD2,183)-(J+A-2,K+1),C-1,BF:LINE(J+KMOD2,K)-(J+A-2,K-(7*P+L)MOD5),C,BF:FORB=182TOK+1STEP-4:FORC=J+2TOJ+A-3STEP2:PSET(C,B),10:NEXT:NEXT:NEXT:GOTO9
' Subroutine:
' - Draw buildings between the current (P) and next NASAMS component. Color, width, height, and depth are picked by hashing formulas.

'___5___10___15___20___25___30___35___40___45___50___55___60___65___70___75___80___85___90___95__100__105__110__115__120__125__130__135__140__145__150__155__160__165__170__175__180__185__190__195__200__205__210__215__220__225__230__235__240__245__250__255
7SOUND7,190:L=0:Z=-32:IFQ<0THENA$="V15T100L8GEL4AL2EO4":PLAY"O3"+A$:PLAYA$:Q=0:GOTO1ELSEA$="V15T160O4L4GGBL8GL4ABAGF#DG.L8AL4BAL2G":A$=A$+A$:PLAYA$:A$="L4BO5DFL8ET120FGFEDCDEDCO4BAT160L4GBO5D.L8C#T120DEDCO4BAGBL4O5DCL8O4BAL4L2G":PLAYA$:PLAYA$:Q=0:GOTO1
' - Plays either the defeat melody (fragment of ruzzian "Dubinushka")
'             or the victory melody (fragment of Ukrainian "Oi u luzi chervona kalyna").
' Note: I am not a musician at all, so sorry for inexactness.

'___5___10___15___20___25___30___35___40___45___50___55___60___65___70___75___80___85___90___95__100__105__110__115__120__125__130__135__140__145__150__155__160__165__170__175__180__185__190__195__200__205__210__215__220__225__230__235__240__245__250__255
8IFZ=209THENRETURNELSESPRITEOFF:RESTORE8:FORI=0TO4:READA,B:SOUNDA,B:NEXT:FORI=0TO7:CIRCLE(V+7,Z+7),I,9:NEXT:F=Z<160:N=N-F:FORI=7TO0STEP-1:CIRCLE(V+7,Z+7),I,10+3*F:NEXT:Q=Q-(F+1+F)*L:Y=-32:Z=209:LINE(103,191)-(40,184),10,BF:PRINT#1,Q;:RETURN:DATA7,183,8
' Subroutine:
' - Do nothing if enemy object is idle, otherwise draw the explosion effect (expanding and collapsing circles);
' - Ajust score (decrease if ground is reached, increase otherwise, as it was intercepted by our SL-AMRAAM).
' DATA:
' - Explosion effect register/value for SOUND.

'___5___10___15___20___25___30___35___40___45___50___55___60___65___70___75___80___85___90___95__100__105__110__115__120__125__130__135__140__145__150__155__160__165__170__175__180__185__190__195__200__205__210__215__220__225__230__235__240__245__250__255
9A=80*P+1:LINE(A-1,176)-(A+14,183),2,BF:IFL=PTHENRETURNELSEFORI=0TO2:LINE(A,160)-(A+3,170),3,BF:B=166:FORJ=0TO1:LINE(A,B)-(A+3,B+3),12,B:LINE(A+1,B+1)-(A+2,B+2),10-2*(M(P)>3*J+I),B:B=B+5:NEXT:A=A+5:NEXT:RETURN:DATA16,6,2,12,32,13,0,GAME,,OVER,,YOU,,WIN
' Subroutine:
' - Draw the NASAMS component base, for AN/TPQ-36A radar that is all;
' - Draw six launch rails, filled or empty based on counter in M().
' DATA:
' - Explosion effect register/value for SOUND;
' - "GAME OVER" and "YOU WIN" messages.

Можливо, поважне журі трохи втомилося від війни, бо гра зайняла лише 9-те місце:

► Показати

Втім, я отримав ось такий фідбек:

Yes, I think it's hard for us to understand how difficult it really is to live in Ukraine these days. Daily life somehow goes on - for a year now - despite the mortal threat. Your games play like "normal" war games from the 80's that I played detached from their meaning in my youth. Now when I play your games, it's a completely different experience. I have to remember that it has a real, horrible background. It triggers emotions in me. You have found a way to express your anger, your sadness, your fighting spirit, your hope and your fear and send it out into the world.

а також визнання мого скромного таланту геймдизайнера у зовсім несподіваному місці.

Яка гра буде наступною? Нептун? HIMARS? І чи буде вона?
Хочу, щоб більше українців приймали участь у цьому захопливому конкурсі, про який пишуть навіть вельми поважні видання.
Слава Україні!

Героям слава!

Re: Конкурс BASIC 10 Liner Contest

Додано: 18 квітня 2023, 12:31

Nick

Маю надію, що хтось з читачів спробує себе у написанні екстремально коротких ігор (чи інших програм) на BASIC, та прийме участь у наступному конкурсі. Хочу поділитися деякими загальними роздумами та специфічними прийомами програмування.

Можливо ви великий фанат певного ретрокомп'ютера, скажімо [ur=https://en.wikipedia.org/wiki/ZX81l]Sinclair ZX81[/url]. Але це не означає, що він є хорошим вибором для вашої 10-рядкової гри, якщо тільки метою не є участь без перемоги. Наприклад, Microsoft BASIC у Mattel Aquarius дозволяє лише 72 символи у рядку. Це один втрачений рядок у PUR-80, бо 72×10=80×9. Було багато надходжень для цієї платформи, але жодне не виграло зі зрозумілих причин. Деякі діалекти, зокрема Бейсик Вільнюс у БК0010-01, забороняють декілька операторів у одному рядку, роблячи задачу програміста вкрай складною.

Деякі платформи мають функції, корисні для створення ігор на BASIC. Незважаючи на згадане обмеження довжини рядка, Mattel Aquarius пропонує набір символів, що містить ігрових персонажів, стіни, вибухи тощо. Меншою мірою це стосується набору символів Commodore PETSCII та деяких інших платформ. Таким чином, можна виводити таких персонажів (PRINT) або заносити їх безпосередньо у відеопам’ять (POKE), створюючи привабливу ігрову графіку:

AquariusCharset.png

Іноді платформа не визначає псевдографічні символи, але користувач може перепрограмувати окремі гліфи. Це додає ще більше гнучкості, проте не безкоштовно — визначення нових символів (часто в операторах DATA) займає місце у програмі. ZX Spectrum пропонує UDG (User Defined Graphics) для цієї мети:

ColorLines.png

Є платформи з багатими можливостями, такі як MSX. Ви можете визначити апаратні спрайти у спосіб подібний до UDG символів, але позиціонувати їх з піксельною точністю (PUT SPRITE), і пересувати заданням нових координат без жодної потреби у відновленні фону в попередній позиції:

SCRSHOT2.PNG

Останнім, але не менш важливим, є швидкодія обраної платформи. Деякі комп'ютери та діалекти BASIC є повільнішими за інші, і певні алгоритми просто не підходять для реалізації на ретроплатформі.

Нижче ми називатимемо MS BASIC інтерпретатори Microsoft (включно з MSX і PC), а інтерпретатори Sinclair — ZX BASIC. Деякі приклади наведено для обох, оскільки підходи Білла Гейтса і Стіва Вікерса радикально відрізнялись.

Re: Конкурс BASIC 10 Liner Contest

Додано: 18 квітня 2023, 14:14

Nick

Цілочисельні обчислення

Деякі діалекти, такі як Integer BASIC Стіва Возняка для Apple II, оперують виключно цілими числами. Інші, як то ранні інтерпретатори Microsoft, завжди працюють з плаваючою комою.
MSX BASIC та подібні діалекти пропонують як цілі, так і числа з плаваючою комою. Додавання суфікса % до імені змінної робить її цілочисельною, і код, що оперує цілочисельними змінними, працюватиме набагато швидше, що дуже корисно для програмування ігор.

Але в програмі з 10 рядків кожен символ має значення, і % після кожної змінної наближає нас до межі. На щастя, є рішення:

Код: Виділити все

DEFINT A-Z

оголошує всі змінні цілочисельними. Ви можете оголосити підмножину, наприклад імена, що починаються з C, I, J та K:

Код: Виділити все

DEFINT C,I-K

Якщо є багато рядкових змінних, той самий підхід можна застосувати, щоб усунути зайві суфікси $:

Код: Виділити все

DEFSTR A-D,S

оголошує рядкові змінні, імена яких починаються на A, B, C, D і S.

Re: Конкурс BASIC 10 Liner Contest

Додано: 18 квітня 2023, 14:17

Nick

Приберіть зайве

Усуньте пробіли, де це можливо. Для Microsoft BASIC немає різниці між

Код: Виділити все

1 FOR I=1 TO 10

та

Код: Виділити все

1FORI=1TO10

У деяких діалектах ви також можете опускати нулі в операторах DATA:

Код: Виділити все

DATA 1,0,2,0,0,3

дорівнює

Код: Виділити все

DATA1,,2,,,3

Нумерація рядків від 0 дає вам один додатковий символ, оскільки останній рядок буде 9 замість 10. Іноді цей дешевий трюк врятує ваш проєкт.
До речі, оператори DATA дозволені скрізь. Якщо є заповнені рядки, які не досягають ліміту категорії, ви можете помістити DATA туди:

Код: Виділити все

1 xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx:DATA1,2,3,4,5
2 xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx:DATA6,7
3 xxxxxxxxxxxxxxxxxxxxxxxxxxxx:DATA8,9,Hello,World

де xx…xx є деяким значущим кодом на BASIC.
Крім того, DATA/READ може усунути присвоєння, ще більше стиснувши ваш код на ZX BASIC:

Код: Виділити все

1 LET a=16384: LET x=128: LET y=96: LET u=32: LET v=0: LET w=80

можна записати як

Код: Виділити все

1 READ a,x,y,u,v,w: DATA 16384,128,96,32,0,80

Re: Конкурс BASIC 10 Liner Contest

Додано: 18 квітня 2023, 14:21

Nick

Ліворуч чи праворуч?

Найбільш типова проблема в грі - керувати якимось об'єктом за допомогою клавіатури. Розглянемо один вимір, де x — горизонтальна координата, а дозволений діапазон — від 0 до 199. Наш BASIC не підтримує конструкцію ELSE. Клавіша [o] використовується для переміщення вліво, а [p] — вправо:

Код: Виділити все

0 LET x=99
1 REM Draw sprite
2 LET k$=INKEY$ : IF k$="" THEN GOTO 2
3 IF k$="o" AND x>0 THEN LET x=x-1
4 IF k$="p" AND x<199 THEN LET x=x+1
5 GOTO 1

Нам безумовно потрібен більш компактний спосіб виразити дії, зроблені в рядках 3 і 4.
У ZX BASIC результатом логічного виразу, наприклад k$="o" AND x>0, є або 1 (істина), або 0 (хиба). Отже, ми можемо вилучити рядки 4-5 і переписати рядок 3 як:

Код: Виділити все

3 LET x=x-(k$="o" AND x>0)+(k$="p" AND x<199) : GOTO 1

Як це працює?

[o] і може рухатися вліво: x = x-1+0 = x-1
[p] і може рухатися вправо: x = x-0+1 = x+1
жодне: x = x-0+0 = x

У MS BASIC результатом логічного виразу є -1 (істина) або 0 (хиба), тому нам просто потрібно змінити знаки:

Код: Виділити все

3 x=x+(k$="o" AND x>0)-(k$="p" AND x<199) : GOTO 1

Щоб перемістити об’єкти з заданим кроком (наприклад, 8), просто помножте відповідний логічний вираз:

Код: Виділити все

3 x=x+8*(k$="o" AND x>0)-8*(k$="p" AND x<199) : GOTO 1

Re: Конкурс BASIC 10 Liner Contest

Додано: 18 квітня 2023, 14:24

Nick

"Булеві" фокуси

Тут ми поговоримо про кон'юнкцію і диз'юнкцію. Незважаючи на назву розділу, результати цих операцій не є булевими і відрізняються між діалектами. Розглянемо тестову програму:

Код: Виділити все

1 PRINT "1. "; 2>1 AND 13
2 PRINT "2. "; 2<1 AND 13
3 PRINT "3. "; 2>1 OR 13
4 PRINT "4. "; 2<1 OR 13
5 PRINT "5. "; 13 AND 2>1
6 PRINT "6. "; 13 AND 2<1
7 PRINT "7. "; 13 OR 2>1
8 PRINT "8. "; 13 OR 2<1

яка виведе такі результати:

+----+---------+
|Test|  BASIC  |
|    +----+----+
| No.| MS | ZX |
+----+----+----+
|  1 | 13 |  1 |
|  2 |  0 |  0 |
|  3 | -1 |  1 |
|  4 | 13 |  1 |
|  5 | 13 | 13 |
|  6 |  0 |  0 |
|  7 | -1 |  1 |
|  8 | 13 | 13 |
+----+----+----+

Найкорисніший результат показаний у тестах 5 і 6. В обох діалектах,

Код: Виділити все

IF e THEN LET x=v ELSE LET x=0

можна записати як

Код: Виділити все

LET x=v AND e

де e — логічний вираз, а v — будь-яке ціле число. Якщо v є з плаваючою комою, трюк також працює для ZX BASIC, тоді як MS BASIC залишає лише цілу частину (оскільки логічні операції там є, по суті, побітовими).
Інші вирази залежать від платформи і менш корисні, але все ще застосовні для специфічних завдань, заощаджуючи трохи місця в програмі.

Re: Конкурс BASIC 10 Liner Contest

Додано: 18 квітня 2023, 14:26

Nick

Такий потрібний ENDIF

Недоліком більшості інтерпретаторів BASIC є відсутність оператора ENDIF. Конструкції THEN і ELSE (за наявності) діють до кінця рядка. Це значно ускладнює вираження ваших ідей у десяти рядках.

Код: Виділити все

0 REM This is just a dream
1 INPUT x: IF x > 5 THEN PRINT "Here": ENDIF: PRINT "There"

Деякі прийоми для подолання цього обмеження вже були представлені вище. Але є спосіб написати явний IF ... ENDIF: просто використовуйте оператор FOR ... NEXT.

Код: Виділити все

0 REM This is reality (ZX BASIC)
1 INPUT x: FOR i=1 TO x>5: PRINT "Here": NEXT i: PRINT "There"

Як відомо, x>5 дає 1 для істинної умови, тому цикл буде виконано один раз. Для хибної умови він перетворюється на FOR i=1 TO 0, тому тіло циклу буде пропущено.
Для MS BASIC x>5 дає -1 для істинної умови, тому ми можемо записати це як:

Код: Виділити все

0 REM Is this still just a dream? (MS BASIC)
1 INPUT x: FOR i=x>5 TO -1: PRINT "Here": NEXT: PRINT "There"

На жаль, Білл Гейтс вирішив виконати тіло циклу, перш ніж перевірити умову його завершення, і трюк не працює на ранніх інтерпретаторах Microsoft, включно з MSX BASIC. Однак він працює на IBM PC.